MODIFY_TASK

Verwenden Sie die Script-Funktion MODIFY_TASK, um aktive STANDARD-Workflows und Aufgaben in aktiven STANDARD-Workflows zu ändern. Sie können sie nicht für IF- oder FOREACH-Workflows verwenden. MODIFY_TASK Lässt Sie die Aufgabeneigenschaften für einen bestimmten Workflow ändern, ohne die Objektdefinitionen zu bearbeiten. Die Aufgabeneigenschaften im Workflow überschreiben die Einstellungen in der Objektdefinition. Weitere Informationen finden Sie unter Aufgabeneigenschaften in Workflows.

Diese Seite beinhaltet Folgendes:

Übersicht

Vor und nach Änderungen mit MODIFY_TASK müssen Sie den Workflow-Status immer mit vorläufigen  MODIFY_TASK-Script-Zeilen ändern. Befolgen Sie diese Reihenfolge, wenn Sie einen Workflow mit MODIFY_TASK ändern:

  1. Verwenden Sie MODIFY_TASK mit dem Parameter STOP_MODIFY, um den Workflow anzuhalten und die Bearbeitung zu ermöglichen.
  2. Verwenden Sie MODIFY_TASK mit anderen Parametern, um eine oder mehrere Änderungen am Workflow vorzunehmen.
  3. Verwenden Sie MODIFY_TASK mit dem Parameter COMMIT, um Ihre Änderungen zu aktivieren.
  4. Verwenden Sie MODIFY_TASK mit dem GO-Parameter, um den Workflow zu starten.

Syntax und Parameter

Die grundlegende Syntax dieser Script-Funktion enthält die folgenden Elemente:

MODIFY_TASK (RunID, Parameter, KEYWORD)

Wobei:

  • MODIFY_TASK

    Ändert einen aktiven Workflow

  • RunID
    RunID des aktiven Workflows, der geändert werden soll

  • Parameter
    Ein oder mehrere Parameter geben an, welche Aufgabe geändert werden soll, oder andere Parameter, je nach Änderung

  • KEYWORD
    Gibt die Aktion an, die durchgeführt werden soll
    Alle verfügbaren Schlüsselwörter werden in diesem Thema beschrieben.
    Hinweis:Einige Schlüsselwörter haben zusätzliche Parameter nach dem Schlüsselwort.

Wichtig!

  • Sie müssen die Parameter von MODIFY_TASK in der Reihenfolge schreiben, in der sie in den Syntaxbeispielen in diesem Thema angezeigt werden.
  • Sie müssen Kommas verwenden, wie in den Syntaxbeispielen gezeigt, auch wenn Sie einzelne Parameter weglassen.

Mehrere Änderungen, die Sie mit MODIFY_TASK durchführen können, erfordern, dass Sie eine bestimmte Aufgabe angeben. Verwenden Sie einen oder beide der folgenden Parameter, um die Aufgabe anzugeben:

  • Aufgabenname
    Name der Aufgabe
    Hinweis: Verwenden Sie START oder END wenn Sie das Start- oder Endfeld eines Workflows ändern möchten
    Format: Script-Literal, Zahl oder Script-Variable.

  • Sequenznummer
    Sequenznummer der Aufgabe
    Die Sequenznummer bezieht sich auf die Nummer innerhalb des Workflows, wie beispielsweise 3 für die dritte Aufgabe. Die Sequenznummer wird in dem Aufgabenfeld des Workflow-Editors angezeigt. Die Sequenznummer ist nicht die RunID. Weitere Informationen finden Sie unter Aufgabenfelder in Workflows .
    Format: Script-Literal, Zahl oder Script-Variable.

Hinweise:

  • Wenn Sie sowohl den Aufgabennamen als auch die Sequenznummer angeben, stellen Sie sicher, dass diese mit der gleichen Aufgabe übereinstimmen.
  • Wenn es im Workflow mehrere Aufgaben mit gleichem Namen gibt und Sie keine Sequenznummer angeben, verwendet das System die Aufgabe mit der niedrigsten Nummer.

Beispielszenario

Sie möchten zwei Aufgaben zu einem Workflow hinzufügen, wenn der Workflow aktiv ist. Dieses Beispiel zeigt, wie man MODIFY_TASK-Funktionen mit mehreren verschiedenen Schlüsselwörtern kombiniert, um die Aufgaben hinzuzufügen und zu platzieren und die erforderlichen Abhängigkeiten zu erstellen.

Voraussetzungen:

  • Workflow-Objekt
    Für die Zwecke dieses Beispiels hat der Workflow derzeit eine Child-Aufgabe.
  • Zwei ausführbare Objekte (Aufgabe.01 und Aufgabe.02)

Ziele:

  • Beide Aufgaben sind abhängig von ihren Vorgängern im Workflow:
    • Aufgabe.01 beginnt direkt beim Start des Workflows.
    • Aufgabe.02 startet nach Beendigung von Aufgabe.01.
  • Der Workflow endet mit dem Ende der Aufgabe.02.

Schreiben Sie das folgende Script auf der Prozess-Seite der Unteraufgabe, die sich gerade im Workflow befindet.

Syntax

:SET &RUNID# = SYS_ACT_PARENT_NR(ACT)

:PRINT &RUNID#

:SET &RET# = MODIFY_TASK(&RUNID#, STOP_MODIFY)

:SET &RET# = MODIFY_TASK(&RUNID#, 'TASK.01', ,ADD_TASK)

:SET &RET# = MODIFY_TASK(&RUNID#, 'TASK.01', ,MOVE_TASK, 2, 3)

:SET &RET# = MODIFY_TASK(&RUNID#, 'TASK.01', ,ADD_DEPENDENCY, 'START', , 'NONE' )

 

:SET &RET# = MODIFY_TASK(&RUNID#, 'TASK.02', ,ADD_TASK)

:SET &RET# = MODIFY_TASK(&RUNID#, 'TASK.02', ,MOVE_TASK, 3, 3)

:SET &RET# = MODIFY_TASK(&RUNID#, 'TASK.02', ,ADD_DEPENDENCY, 'TASK.01', , 'NONE' )

 

:SET &RET# = MODIFY_TASK(&RUNID#, 'END', ,ADD_DEPENDENCY, 'TASK.02', , 'NONE' )

:SET &RET# = MODIFY_TASK(&RUNID#, 'END', ,REMOVE_DEPENDENCY, 'START', , 'NONE' )

:SET &RET# = MODIFY_TASK(&RUNID#, COMMIT)

:SET &RET# = MODIFY_TASK(&RUNID#, GO, FORCED)

Parameter

  • SYS_ACT_PARENT_NR
    Ruft die RunID des Workflows ab, in dem sich die Aufgabe befindet

  • PRINT
    Gibt die abgerufene RunID im Aktivierungsreport aus

  • MODIFY_TASK
    Führt eine Änderung am Workflow oder an einer Aufgabe im Workflow durch

  • STOP_MODIFY
    Stoppt den Workflow für Änderungen

  • ADD_TASK
    Fügt dem Workflow eine Aufgabe hinzu

  • MOVE_TASK
    Verschiebt die hinzugefügte Aufgabe an die gewünschte Stelle (gekennzeichnet durch Spalte und Zeile) im Workflow

  • ADD_DEPENDENCY
    Zeichnet eine Linie zum Vorgänger der hinzugefügten Aufgabe, um eine Abhängigkeit zu erstellen

  • REMOVE_DEPENDENCY
    Löscht die Linie zu einer Vorgängeraufgabe, um die Abhängigkeit zu entfernen

  • COMMIT
    Übernimmt die Änderungen am Workflow

  • GO, FORCED
    Startet den Workflow wieder, auch wenn ein anderer Benutzer ihn zur Bearbeitung geöffnet hat

Rückgabewerte

MODIFY_TASK hat je nach Art der Änderung folgende Rückgabewerte.

  • 0

    Die Änderung war erfolgreich
  • 9

    Sie sind nicht berechtigt, die angegebene Aufgabe zur Laufzeit zu ändern
  • 20591

    Ein Workflow mit dieser RunID existiert nicht oder ist nicht mehr aktiv
  • 20738

    Die Aufgabe befindet sich in einem Zustand, in dem Änderungen nicht möglich sind
  • 20739

    Die Aufgabe kann nicht geändert werden, da sie von einem anderen Benutzer geändert wird
  • 20740

    Der von Ihnen angegebene Objekttyp ist ungültig
  • 20741

    Es gibt keine Aufgabe mit dem angegebenen Namen und/oder der RunID
  • 20742

    Der angegebene Aufgabenname und die RunID stimmen nicht mit der gleichen Aufgabe überein
  • 20743

    Die Aufgabe kann nicht geändert werden, da der entsprechende Workflow nicht zur Bearbeitung gestoppt wurde
  • 20744

    Die Aufgabe kann nicht geändert werden, da sie sich in einem unveränderlichen Zustand befindet
  • 20745

    Die Aufgabe kann nicht geändert werden, da der Wert nicht erlaubt ist
  • 20746

    Die Abhängigkeit kann nicht hinzugefügt werden, da sie bereits existiert
  • 20747

    Die Abhängigkeit kann nicht geändert werden, da sie sich in einem unveränderlichen Zustand befindet
  • 20748

    Die Aufgabe kann nicht hinzugefügt werden, da diese Position bereits von einer anderen Aufgabe besetzt ist
  • 20749

    Der Objekttyp der angegebenen Aufgabe ist ungültig
  • 20750

    Die Funktion kann für diese Aufgabe mit der spezifischen RunID aufgrund eines früheren Fehlers nicht verarbeitet werden
  • 20752

    Sie können externe Aufgaben nur durch externe Aufgaben ersetzen
  • 20753

    Sie können <START> oder <END> nicht ersetzen
  • 20754

    <START> kann keinen Vorgänger haben
  • 20755

    <END> kann keinen Nachfolger haben
  • 20756

    Externe Aufgaben können keinen Vorgänger haben
  • 20757

    Die Aufgabe, die Sie für die Änderung einer externen Abhängigkeit angegeben haben, ist ungültig
  • 20758
    Externe Abhängigkeiten können nicht angezeigt werde
  • 20783
    MODIFY_TASK ist nicht möglich für Workflow '&01' (RunID '&02') des Typs '&03'.

MODIFY_TASK, ADD_TASK hat die folgenden Rückgabewerte:

  • Laufende Nummer der Aufgabe, die Sie dem Workflow hinzugefügt haben
  • 0 - die Aufgabe konnte nicht hinzugefügt werden

MODIFY_TASK, REPLACE_TASK und MODIFY_TASK, CLONE_AND_REPLACE_TASK haben die folgenden Rückgabewerte:

  • Laufende Nummer der Aufgabe, die Sie dem Workflow hinzugefügt haben
  • 0 - die Aufgabe konnte nicht ersetzt werden

Stoppen, Bestätigen von Änderungen und Starten des Workflows

Verwenden Sie MODIFY_TASK mit Statusparametern, um den Workflow zu stoppen, Ihre Änderungen zu übernehmen und zu übertragen und den Workflow erneut zu starten. Sie müssen den Workflow stoppen und starten, um die anderen in diesem Thema beschriebenen MODIFY_TASK-Parameter zu verwenden.

Syntax

MODIFY_TASK (RunID, Status [, FORCED])

Parameter

  • Status
    Für den Workflow zu setzender Status
    Format: AE-Name, Script-Literal oder Script-Variable
    Zulässige Werte:

    • COMMIT
      Aktiviert Änderungen, ohne den Workflow zu starten
    • GO
      Startet einen angehaltenen Workflow
      Verwenden Sie den Parameter FORCED, um einen Workflow zu starten, auch wenn sein Monitor zur Bearbeitung geöffnet ist
    • STOP
      Stoppt den Workflow
    • STOP_MODIFY
      Stoppt den Workflow für Änderungen

  • FORCED
    (Optional) Startet einen angehalten Workflow, auch wenn der Workflow-Monitor zum Bearbeiten geöffnet ist
    Verwenden Sie dieses Schlüsselwort in Kombination mit dem Status GO.
    Wichtig! Änderungen, die von einem anderen Benutzer vorgenommen werden, gehen verloren, wenn Sie den Workflow während der Bearbeitung stoppen.

Hinweise:

  • Sie können einen Workflow nicht ändern, indem Sie eine MODIFY_TASK-Anweisung auf der eigenen Prozessseite des Workflows verwenden.
  • Sie können jedoch einen Workflow ändern, indem Sie eine MODIFY_TASK-Anweisung auf der Prozess-Seite einer untergeordneten Aufgabe verwenden, wie z. B. ein Script (SCRI).

Beispiele

Das folgende Beispiel stoppt den MM.DAY-Workflow und ermöglicht es Ihnen, Änderungen vorzunehmen.

:SET &RUNID# = GET_UC_OBJECT_NR("MM.DAY")
:SET &RET# = MODIFY_TASK(&RUNID#, STOP_MODIFY)

Das folgende Beispiel startet den MM.DAY Workflow, auch wenn ein anderer Benutzer den Workflow bearbeitet.

:SET &RUNID# = GET_UC_OBJECT_NR("MM.DAY")
:SET &RET# = MODIFY_TASK(&RUNID#, GO, FORCED)

Workflow-Inhalte ändern

Mit den folgenden Schlüsselwörtern können Sie den Inhalt eines aktiven Workflows ändern:

  • ADD_TASK
    Fügt dem Workflow eine Aufgabe hinzu

  • REPLACE_TASK oder CLONE_AND_REPLACE
    Ersetzt eine Aufgabe im Workflow

  • MOVE_TASK
    Verschiebt eine Aufgabe im Workflow an eine andere Position innerhalb des Workflows

  • ACTIVE
    Aktiviert oder deaktiviert eine Workflow-Aufgabe

Eine Aufgabe oder externe Abhängigkeit hinzufügen

Verwenden Sie MODIFY_TASK mit ADD_TASK, um einem aktiven Workflow eine Aufgabe hinzuzufügen. Verwenden Sie das Schlüsselwort EXTERNAL, um eine Aufgabe als externe Abhängigkeit hinzuzufügen.

Die Aufgabe, die Sie hinzufügen, ist nicht automatisch mit anderen Aufgaben verknüpft. Verwenden Sie MODIFY_TASK mit ADD_DEPENDENCY, um die erforderlichen Linien zu zeichnen. Verwenden Sie MODIFY_TASK mit MOVE_TASK, um die Aufgabe an die richtige Stelle im Workflow zu bringen.

Syntax

MODIFY_TASK (RunID, Objektname ,, ADD_TASK [, EXTERNAL [, Workflow-Name]] )

Parameter

  • Objektname
    Name des Objekts, das in das Workflow-Format eingefügt werden soll
    Format: Script-Literal, Zahl oder Script-Variable

  • ADD_TASK
    Fügt die Aufgabe hinzu

  • EXTERNAL
    (Optional) Fügt die Aufgabe als externe Abhängigkeit hinzu

  • Workflow-Name
    (Optional) Name des Workflows, auf den die externe Abhängigkeit verweist
    Format: Script-Literal oder Script-Variable

Hinweise:

  • Schreiben Sie 2 Kommas nach dem Parameter object name. Dieser dritte Parameter ist die Sequenznummer einer Aufgabe innerhalb des Workflows. Er hat jedoch für das Hinzufügen einer Aufgabe keine Bedeutung.
  • Wenn der Workflow so konfiguriert ist, dass Aufgaben die Priorität AE des Workflows erben, dann bekommt die Aufgabe, die Sie hinzufügen, auch diese Priorität.

Tipp: Verwenden Sie die Sequenznummer, die die Funktion zurückgibt, um die Aufgabe anzugeben, wenn Sie andere Änderungen an der hinzugefügten Aufgabe vornehmen.

Beispiel

Das folgende Beispiel fügt dem Workflow MM.DAY das Objekt FILE.INPUT hinzu.

: SET  &RUNID# = GET_UC_OBJECT_NR ( "MM.DAY" )
: SET  &RETSTOP# = MODIFY_TASK ( &RUNID# , STOP_MODIFY)
: SET  &RET# = MODIFY_TASK ( &RUNID# , "FILE.INPUT" ,, ADD_TASK)
: SET  &RETCOMMIT# = MODIFY_TASK ( &RUNID# , COMMIT)
: SET  &RETGO# = MODIFY_TASK ( &RUNID# , GO)

Aufgabe in einem Workflow ersetzen

Verwenden Sie MODIFY_TASK mit REPLACE_TASK oder CLONE_AND_REPLACE, um eine bestimmte Aufgabe im Workflow durch ein anderes Objekt zu ersetzen. Sie können eine externe Abhängigkeit nur durch eine externe Abhängigkeit und eine normale Workflow-Aufgabe durch eine normale Workflow-Aufgabe ersetzen.

Syntax

MODIFY_TASK (RunID, [Aufgabenname], [Sequenznummer], REPLACE_TASK|CLONE_AND_REPLACE , Objektname [, EXTERNAL [, Workflow-Name]])

Parameter

  • REPLACE_TASK oder CLONE_AND_REPLACE
    Ersetzt die Aufgabe durch das von Ihnen angegebene Objekt

    • REPLACE_TASK 
      Setzt den Status der alten, ersetzten Aufgabe auf inaktiv
    • CLONE_AND_REPLACE
      Behält die alte Aufgabe aktiv

  • Objektname
    Name des Objekts, durch das die Aufgabe ersetzt werden soll
    Format: Script-Literal oder Script-Variable

  • EXTERNAL
    Ersetzt eine externe Abhängigkeit

  • Workflow-Name
    Name des Workflows, auf den die externe Abhängigkeit verweist
    Format: Script-Literal oder Script-Variable

Beispiel

Das folgende Beispiel verwendet MODIFY_TASK mit REPLACE_TASK, um eine externe Abhängigkeit (MM.GET.FILES) durch eine andere externe Abhängigkeit (MM.FILE.INPUT) zu ersetzen.

:SET &RUNID# = GET_UC_OBJECT_NR("MM.DAY")
:SET &RETSTOP# = MODIFY_TASK(&RUNID#, STOP_MODIFY)
:SET &RET# = MODIFY_TASK(&RUNID#, "MM.GET.FILES",, REPLACE_TASK, "MM.FILE.INPUT", EXTERNAL)
:SET &RETCOMMIT# = MODIFY_TASK(&RUNID#, COMMIT)
:SET &RETGO# = MODIFY_TASK(&RUNID#, GO)

Aufgabe in einen Workflow verschieben

Wenn Sie MODIFY_TASK zum Hinzufügen einer Aufgabe verwenden, wird die hinzugefügte Aufgabe an einer freien Stelle im Workflow platziert. Verwenden Sie MODIFY_TASK mit MOVE_TASK, um die Aufgabe an die gewünschte Stelle im Workflow zu verschieben. Geben Sie die Spalte und Zeile der gewünschten leeren Stelle an.

Syntax

MODIFY_TASK (RunID, [Aufgabenname], [Sequenznummer], MOVE_TASK , Spalte, Zeile)

Parameter

  • MOVE_TASK
    Verschiebt die Aufgabe

  • Spalte
    Nummer der Spalte, in die die Aufgabe verschoben werden soll
    Format: Script-Literal, Zahl oder Script-Variable

  • Zeile
    Nummer der Zeile, in die die Aufgabe verschoben werden soll
    Format: Script-Literal, Zahl oder Script-Variable

Beispiel

Das folgende Script verschiebt die Aufgabe FILE.INPUT in die vierte Zeile der ersten Spalte.

:SET &RUNID# = GET_UC_OBJECT_NR("MM.DAY")
:SET &RETSTOP# = MODIFY_TASK(&RUNID#, STOP_MODIFY)
:SET &RET# = MODIFY_TASK(&RUNID#, "FILE.INPUT",, MOVE_TASK, 1, 4)
:SET &RETCOMMIT# = MODIFY_TASK(&RUNID#, COMMIT)
:SET &RETGO# = MODIFY_TASK(&RUNID#, GO)

Aktivieren oder Deaktivieren einer Workflow-Aufgabe

Verwenden Sie MODIFY_TASK mit ACTIVE, um eine Aufgabe zu aktivieren oder zu deaktivieren.

Syntax

MODIFY_TASK (RunID, [Aufgabenname], [Sequenznummer], ACTIVE , YES|NO)

Parameter

  • ACTIVE
    ACTIVE Setzt den Status der Aufgabe auf aktiv oder inaktiv

  • YES oder NO
    Legt den Status der Aufgabe fest:

    • YES
      Setzt die Workflow-Aufgabe auf aktiv
      Die Verarbeitung beginnt zu der angegebenen Startzeit
    • NO
      Setzt die Workflow-Aufgabe auf inaktiv
      Die Verarbeitung beginnt nicht zur Startzeit.

Beispiel

Das folgende Beispiel setzt den Status der Aufgabe FILE.INPUT im MM.DAY Workflow auf inaktiv.

:SET &RUNID# = GET_UC_OBJECT_NR("MM.DAY")
:SET &RETSTOP# = MODIFY_TASK(&RUNID#, STOP_MODIFY)
:SET &RET# = MODIFY_TASK(&RUNID#, "FILE.INPUT",, ACTIVE, "NO")
:SET &RETCOMMIT# = MODIFY_TASK(&RUNID#, COMMIT)
:SET &RETGO# = MODIFY_TASK(&RUNID#, GO)

Registerkarte "Allgemein"

Mit den folgenden Schlüsselwörtern können Sie Eigenschaften ändern, die auf der Registerkarte Allgemein einer Workflow-Aufgabe festgelegt sind:

  • ALIAS
    Ändert den Alias einer Aufgabe oder einer externen Abhängigkeit in einem aktiven Workflow

  • ALIAS_PARENT
    Ändert den Alias des Workflows einer externen Abhängigkeit

  • BREAKPOINT
    Setzt einen Haltepunktes in einer Workflow-Aufgabe oder entfernt diesen

Weitere Informationen zu allgemeinen Eigenschaften von Aufgaben in Workflows finden Sie auf der Registerkarte "Allgemein".

Ändern eines Task-Alias

Verwenden Sie MODIFY_TASK mit ALIAS, um den Alias einer Aufgabe oder einer externen Abhängigkeit in einem aktiven Workflow zu ändern.

Hinweis: Sie können den Alias von Workflow-Aufgaben und externen Abhängigkeiten, die Sie hinzugefügt haben, nur mit einer MODIFY_TASK, ADD_TASK-Anweisung im Script ändern.

Syntax

MODIFY_TASK (RunID,[Aufgabenname], [Sequenznummer],ALIAS|ALIAS_PARENT, Neuer Alias|Neuer Parent-Alias)

Parameter

Diese Funktion hat die folgenden Parameter:

  • ALIAS oder ALIAS_PARENT
    Ändert den Aliasnamen einer Aufgabe oder eine externe Abhängigkeit im Workflow
    Verwenden Sie ALIAS_PARENT, um den Alias des Workflows einer externen Abhängigkeit zu ändern (für externe Aufgaben, die nur von einem anderen Workflow abgeleitet werden).

  • Alias-Name oder Parent-Alias-Name
    Neuer Alias-Name
    Format: AE-Name, Script-Literal, Zahl oder Script-Variable
    Weitere Informationen über Alias-Namen finden Sie auf der Registerkarte "Allgemein".

Beispiel

Das folgende Beispiel fügt dem Workflow einen File Transfer hinzu und ändert den Alias der Aufgabe. Der Rückgabewert von MODIFY_TASK, ADD_TASK ist die Sequenznummer der hinzugefügten Aufgabe und wird in einer Script-Variablen (&NR#) gespeichert. Die Script-Variable wird verwendet, um anzugeben, welcher Alias geändert werden soll.

:SET &RUNID# = GET_UC_OBJECT_NR("MM.DAY")
:SET &RETSTOP# = MODIFY_TASK(&RUNID#, STOP_MODIFY)
:SET &NR# = MODIFY_TASK(&RUNID#, "FILE.INPUT",, ADD_TASK)
:SET &RET# = MODIFY_TASK(&RUNID#, "FILE.INPUT",&NR#,ALIAS,ALIAS.FT)
:SET &RETCOMMIT# = MODIFY_TASK(&RUNID#, COMMIT)
:SET &RETGO# = MODIFY_TASK(&RUNID#, GO) 

Setzen oder Entfernen eines Haltepunktes

Verwenden Sie MODIFY_TASK mit BREAKPOINT, um einen Haltepunkt in einer Workflow-Aufgabe zu setzen oder zu entfernen.

Syntax

MODIFY_TASK (RunID, [Aufgabenname], [Sequenznummer], BREAKPOINT, YES|NO)

Parameter

  • BREAKPOINT
    Setzt oder entfernt den Haltepunkt für die Workflow-Aufgabe

  • YES oder NO
    Bestimmt, ob das Schlüsselwort einen Haltepunkt hinzufügt oder entfernt:

    • YES
      Setzt einen Haltepunkt
    • NO
      Entfernt den Haltepunkt

Beispiel

Das folgende Beispiel verwendet MODIFY_TASK mit dem Schlüsselwort BREAKPOINT, um einen Haltepunkt für die Aufgabe FILE.INPUT zu setzen.

:SET &RUNID# = GET_UC_OBJECT_NR("MM.DAY")
:SET &RETSTOP# = MODIFY_TASK(&RUNID#, STOP_MODIFY)
:SET &RET# = MODIFY_TASK(&RUNID#, "FILE.INPUT",, BREAKPOINT, "YES")
:SET &RETCOMMIT# = MODIFY_TASK(&RUNID#, COMMIT)
:SET &RETGO# = MODIFY_TASK(&RUNID#, GO)

Registerkarte "Zeit und Abhängigkeiten"

Mit den folgenden Schlüsselwörtern können Sie Eigenschaften ändern, die auf der Registerkarte Zeit und Abhängigkeiten einer Workflow-Aufgabe festgelegt sind:

  • EARLIEST_START
    Setzt eine früheste Startzeit für eine Workflow-Aufgabe

  • LATEST_START
    Fügt eine späteste Startzeit für eine Workflow-Aufgabe hinzu oder entfernt sie

  • CHECKPOINT
    Fügt einen Kontrollpunkt in einer Workflow-Aufgabe hinzu oder entfernt ihn

  • DEPENDENCY_STATE_MATCH
    Anzahl der Status der Vorgängeraufgabe, die erfüllt sein müssen

Weitere Informationen zu Eigenschaften, die das Timing und die Abhängigkeiten bestimmen, finden Sie unter Zeit und Abhängigkeiten .

Hinzufügen oder Entfernen einer Start- oder Endzeit

Verwenden Sie MODIFY_TASK mit einem Start- oder Endschlüsselwort, um die Start- oder Endzeit einer Aufgabe in einem aktiven Workflow festzulegen oder zu entfernen.

Syntax

MODIFY_TASK (RunID, [Aufgabenname], [Sequenznummer], KEYWORD, Zeitstempel [, Zeitzone])

Parameter

  • KEYWORD
    Setzt oder entfernt die Start- oder Endzeit der Aufgabe:

    • EARLIEST_START
      Setzt oder entfernt die früheste Startzeit der Aufgabe
    • LATEST_START
      Setzt oder entfernt die letzte Startzeit der Aufgabe
    • LATEST_END
      Setzt oder entfernt die letzte Endzeit der Aufgabe

  • Zeitstempel
    Definiert die Zeit
    Format: Script-Literal oder Script-Variable
    Zulässige Werte TT/HH:MM [, Zeit]

    Mit:

    • TT
      Anzahl der Tage, die zum aktuellen Datum hinzugefügt werden sollen
    • HH:MM
      Zeit
    • Zeitzone
      (Optional) Name eines Zeitzonenobjekts, um die Zeit in eine bestimmte Zeit zu konvertieren
      Format: Script-Literal oder Script-Variable
      Weitere Informationen finden Sie unter Zeitzone (TZ).

Hinweis: Der Vergleichswert für die früheste Startzeit ist das reale Datum (der Zeitpunkt, zu dem der oberste Workflow erzeugt wird). Weitere Informationen finden Sie unter Logisches Datum und reales Datum

Beispiele

Das folgende Beispiel setzt die früheste Startzeit für die Aufgabe FILE.INPUT.

:SET &RUNID# = GET_UC_OBJECT_NR("MM.DAY")
:SET &RETSTOP# = MODIFY_TASK(&RUNID#, STOP_MODIFY)
:SET &RET# = MODIFY_TASK(&RUNID#, "FILE.INPUT",, EARLIEST_START, "00/18:00")
:SET &RETCOMMIT# = MODIFY_TASK(&RUNID#, COMMIT)
:SET &RETGO# = MODIFY_TASK(&RUNID#, GO)

Das folgende Beispiel setzt die späteste Startzeit für die Aufgabe.

:SET &RUNID# = GET_UC_OBJECT_NR("MM.DAY")
:SET &RETSTOP# = MODIFY_TASK(&RUNID#, STOP_MODIFY)
:SET &RET# = MODIFY_TASK(&RUNID#, "FILE.INPUT",, LATEST_START, "00/10:00")
:SET &RETCOMMIT# = MODIFY_TASK(&RUNID#, COMMIT)
:SET &RETGO# = MODIFY_TASK(&RUNID#, GO)

Das folgende Beispiel setzt die späteste Endzeit für die Aufgabe.

:SET &RUNID# = GET_UC_OBJECT_NR("MM.DAY")
:SET &RETSTOP# = MODIFY_TASK(&RUNID#, STOP_MODIFY)
:SET &RET# = MODIFY_TASK(&RUNID#, "FILE.INPUT",, LATEST_END, "00/18:00")
:SET &RETCOMMIT# = MODIFY_TASK(&RUNID#, COMMIT)
:SET &RETGO# = MODIFY_TASK(&RUNID#, GO)

Hinzufügen oder Entfernen eines Kontrollpunkts

Verwenden Sie MODIFY_TASK mit CHECKPOINT, um einen Kontrollpunkt in einer Aufgabe eines aktiven Workflows hinzuzufügen oder zu entfernen.

Syntax

MODIFY_TASK (RunID, [Aufgabenname], [Sequenznummer], CHECKPOINT, Zeitstempel [, Zeitzone] [, Alarmobjekt])

Parameter

  • CHECKPOINT
    Setzt oder entfernt einen Kontrollpunkt

  • Alarmobjekt
    (Optional) Objekt, das gestartet werden soll, wenn der Prüfpunkt übergeben wird
    Format: Script-Literal oder Script-Variable

Beispiel

Das folgende Beispiel setzt einen Kontrollpunkt in einer Aufgabe namens FILE.INPUT, die Teil des MM.DAY-Workflows ist. Nach Ablauf des Kontrollpunkts startet ein Benachrichtigungsobjekt mit dem Namen DAYSHIFT.

:SET &RUNID# = GET_UC_OBJECT_NR("MM.DAY")
:SET &RETSTOP# = MODIFY_TASK(&RUNID#, STOP_MODIFY)
:SET &RET# = MODIFY_TASK(&RUNID#, "FILE.INPUT",, CHECKPOINT, "00/15:00",,"DAYSHIFT")
:SET &RETCOMMIT# = MODIFY_TASK(&RUNID#, COMMIT)
:SET &RETGO# = MODIFY_TASK(&RUNID#, GO)

Ermitteln der Anzahl der erforderlichen Status der Vorgänger

Verwenden Sie MODIFY_TASK mit DEPENDENCY_STATE_MATCH, um festzulegen, ob ein oder alle Status der Vorgänger gelten müssen, bevor die Workflow-Aufgabe bearbeitet wird. Auf der Registerkarte Zeit und Abhängigkeiten in den Aufgabeneigenschaften trägt diese Einstellung die Bezeichnung Diese Aufgabe ausführen, wenn alle Status übereinstimmen/ mindestens eine Bedingung erfüllt ist.

Syntax

MODIFY_TASK (RunID, [Aufgabenname], [Sequenznummer], DEPENDENCY_STATE_MATCH , ALL|ONE)

Parameter

  • DEPENDENCY_STATE_MATCH
    Gibt die Anzahl der Vorgängerstatus an, die zutreffen müssen

  • ALL oder ONE
    Wie viele Vorgängerstatus zutreffen müssen:

    • ALL
      Alle Status müssen zutreffen
    • ONE
      Mindestens ein Status muss zutreffen

Beispiel

Das folgende Beispiel verwendet MODIFY_TASK mit dem DEPENDENCY_STATE_MATCH-Schlüsselwort, um sicherzustellen, dass alle Vorgänger der Aufgabe FILE.INPUT den erwarteten Status haben, bevor die Aufgabe bearbeitet wird.

:SET &RUNID# = GET_UC_OBJECT_NR("MM.DAY")
:SET &RETSTOP# = MODIFY_TASK(&RUNID#, STOP_MODIFY)
:SET &RET# = MODIFY_TASK(&RUNID#, "FILE.INPUT",, DEPENDENCY_STATE_MATCH, "ALL")
:SET &RETCOMMIT# = MODIFY_TASK(&RUNID#, COMMIT)
:SET &RETGO# = MODIFY_TASK(&RUNID#, GO)

Hinzufügen, Ändern oder Entfernen einer Abhängigkeit zu einer Workflow-Aufgabe

Verwenden Sie MODIFY_TASK mit einem DEPENDENCY-Schlüsselwort, um eine Abhängigkeit zu einer Aufgabe in einem Workflow hinzuzufügen, zu entfernen oder zu ändern. Die Funktion fügt Zeilen hinzu, entfernt oder ändert sie, die Aufgaben im Workflow-Editor verbinden.

Syntax

MODIFY_TASK (RunID, [Name der Nachfolgeraufgabe], [Sequenznummer], ADD_DEPENDENCY|MODIFY_DEPENDENCY|REMOVE_DEPENDENCY, [Quell-Aufgabenname] , [Sequenznummer], Status)

Parameter

  • Name der Nachfolgeraufgabe oder Sequenznummer
    Name oder Sequenznummer der Nachfolgeraufgabe der Abhängigkeit
    Format: Script-Literal, Zahl oder Script-Variable

  • ADD_DEPENDENCY oder MODIFY_DEPENDENCY oder REMOVE_DEPENDENCY
    Fügt die Abhängigkeit hinzu, ändert sie oder entfernt sie

  • Name der Quellaufgabe oder Sequenznummer
    Name oder Sequenznummer der Aufgabe, deren Abhängigkeit Sie bearbeiten möchten
    Format: Script-Literal, Zahl oder Script-Variable

  • Status
    Erwarteter Status der Vorgängeraufgabe zum Ende der Ausführung der Aufgabe
    Format: Script-Literal oder Script-Variable
    Hinweis: Sie müssen keinen Status angeben, wenn Sie eine Abhängigkeit entfernen.
    Zulässige Werte:

    • Endstatus
      Erwarteter Status der Vorgängeraufgabe
      Beispiel: ENDED_OK
    • NONE
      Der Endstatus der Vorgängeraufgabe wird nicht überwacht

Weitere Informationen zur Angabe von Aufgabennamen und laufenden Nummern finden Sie unter Syntax und Parameter.

Beispiel

Das folgende Beispiel bearbeitet Abhängigkeiten im Workflow:

  • Die 4. Aufgabe erfordert, dass das Startfeld den Status ENDED_OK erhält.
  • Die 9. Aufgabe erfordert, dass die 8. Aufgabe den Status ANY_OK erhält.
  • Die Abhängigkeit der 11. Aufgabe von der 10. Aufgabe wird entfernt.

:SET &RUNID# = GET_UC_OBJECT_NR("MM.DAY")
:SET &RETSTOP# = MODIFY_TASK(&RUNID#, STOP_MODIFY)
:SET &RET# = MODIFY_TASK(&RUNID#,, 4, ADD_DEPENDENCY, "START",, "ENDED_OK")
:SET &RET# = MODIFY_TASK(&RUNID#,, 9, MODIFY_DEPENDENCY,, 8,"ANY_OK")
:SET &RET# = MODIFY_TASK(&RUNID#,, 11, REMOVE_DEPENDENCY,, 10, "ENDED_OK")
:SET &RETCOMMIT# = MODIFY_TASK(&RUNID#, COMMIT)
:SET &RETGO# = MODIFY_TASK(&RUNID#, GO)

Definition einer Aktion, die ergriffen werden soll, wenn Abhängigkeiten nicht erfüllt werden

Verwenden Sie MODIFY_TASK mit DEPENDENCY_ELSE_ACTION, um die Aktion zu definieren, die durchgeführt werden soll, wenn eine Abhängigkeit nicht erfüllt wird.

Syntax

MODIFY_TASK (RunID, [Aufgabenname], [Sequenznummer], DEPENDENCY_ELSE_ACTION , ABORT|BLOCK|BLOCK_ABORT|SKIP [ , Alarmobjekt] )

Parameter

  • DEPENDENCY_ELSE_ACTION
    Legt fest, dass Aktionen ergriffen werden sollen, wenn Abhängigkeiten nicht wie erwartet erfüllt werden

  • ABORT, BLOCK, BLOCK_ABORT oder SKIP
    Definiert die zu ergreifende Aktion:

    • ABORT
      Aufgabe und Workflow wird abgebrochen.
    • BLOCK
      Der Workflow blockiert bei der Vorgängeraufgabe
    • BLOCK_ABORT
      Blockiert den Workflow bei der vorhergehenden Aufgabe und sendet gegebenenfalls eine Abbruchmeldung an den übergeordneten Workflow
    • SKIP
      Überspringt die Workflow-Aufgabe

  • Alarmobjekt
    Name eines Benachrichtigungsobjekts vom Alarmtyp, das gestartet wird, wenn der Prüfpunkt überschritten wird
    Format: Script-Literal oder Script-Variable

Beispiel

Das folgende Beispiel überspringt die Aufgabe FILE.INPUT, wenn die Bedingungen für die Abhängigkeit nicht erfüllt sind.

:SET &RUNID# = GET_UC_OBJECT_NR("MM.DAY")
:SET &RETSTOP# = MODIFY_TASK(&RUNID#, STOP_MODIFY)
:SET &RET# = MODIFY_TASK(&RUNID#, "FILE.INPUT",, DEPENDENCY_ELSE_ACTION, "SKIP")
:SET &RETCOMMIT# = MODIFY_TASK(&RUNID#, COMMIT)
:SET &RETGO# = MODIFY_TASK(&RUNID#, GO)

Registerkarte "Laufzeit"

Mit den folgenden Parametern können Sie die Einstellungen auf der Registerkarte Laufzeit einer Workflow-Aufgabe ändern. Weitere Informationen finden Sie unter Laufzeit-Eigenschaften.

Syntax

MODIFY_TASK (RunID, [Aufgabenname], [Sequenznummer], Laufzeitoption, Wert )

Parameter

  • Laufzeitoption
    Laufzeiteinstellung, die Sie bearbeiten möchten
  • Wert
    Definiert den Wert für die Einstellung, abhängig von der Laufzeiteinstellung, die Sie bearbeiten möchten

Laufzeit-Optionen:

  • RUNTIME_USE_TASK_SETTINGS
    Verwendet die Einstellungen MRT und SRT der Aufgabe
    Zulässige Werte:

    • YES
      Verwendet die für die Aufgabe auf der Registerkarte Laufzeit definierten Laufzeiteinstellungen (Aufgabeneigenschaften im Workflow)
    • NO
      Verwendet die Laufzeiteinstellungen, die in den Eigenschaften auf der Seite Laufzeit in der Objektdefinition definiert sind

  • RUNTIME_MRT_NONE
    Keine maximale Laufzeit angegeben
    Geben Sie keinen Wert ein.

  • RUNTIME_MRT_FIXED
    Verwendet einen festen Wert für die maximale Laufzeit
    Zulässige Werte: Fester Wert im Format HHHH:MM:SS

  • RUNTIME_MRT_ERT
    Verwendet ERT plus einen bestimmten Prozentsatz für die maximale Laufzeit
    Zulässige Werte: Prozentsatz
    Beispiel: Geben Sie 50 an, um 50 % zur maximalen Laufzeit zu addieren.

  • RUNTIME_MRT_TIME
    Verwendet das aktuelle Datum plus einen bestimmten Zeitraum für die maximale Laufzeit
    Zulässige Werte: TT/HH:MM [, Zeitzone]
    Mit:

    • TT
      Anzahl der Tage, die zum aktuellen Datum hinzugefügt werden sollen
    • HH:MM
      Zeit
    • Zeitzone
      (Optional) Name eines Zeitzonenobjekts, um den Zeitstempel zu konvertieren

  • RUNTIME_SRT_NONE
    Keine minimale Laufzeit
    Geben Sie keinen Wert ein.

  • RUNTIME_SRT_FIXED
    Verwendet einen festen Wert für die minimale Laufzeit
    Zulässige Werte: Fester Wert im Format HHHH:MM:SS

  • RUNTIME_SRT_ERT
    Verwendet ERT minus einem bestimmten Prozentsatz für die minimale Laufzeit
    Zulässige Werte: Prozentsatz

  • RUNTIME_ELSE_ACTION
    Definiert eine Aktion, die ausgeführt werden soll, wenn die tatsächliche Laufzeit von der erwarteten Laufzeit abweicht
    Zulässige Werte: CANCEL|NONE [, Alarmobjekt]
    Mit:

    • CANCEL
      Bricht die Aufgabe ab oder beendet sie
    • NONE
      Es werden keine Maßnahmen ergriffen
    • Alarmobjekt
      (Optional) Name eines Benachrichtigungsobjekts eines Alarmtyps, das gestartet werden soll, wenn die erwartete Laufzeit überschritten wird

Beispiel

Das Benachrichtigungsobjekt DAYSHIFT startet, wenn die Ausführung der Aufgabe FILE.INPUT länger als zwei Stunden dauert. Das Script entfernt auch alle minimalen Laufzeiteinstellungen.

:SET &RUNID# = GET_UC_OBJECT_NR("MM.DAY")
:SET &RETSTOP# = MODIFY_TASK(&RUNID#, STOP_MODIFY)
:SET &RETMRT# = MODIFY_TASK(&RUNID#, "FILE.INPUT",, RUNTIME_MRT_FIXED, "2:00:00")
:SET  &RETSRT# = MODIFY_TASK(&RUNID#, "FILE.INPUT",, RUNTIME_SRT_NONE)
:SET  &RETACT# = MODIFY_TASK(&RUNID#, "FILE.INPUT",, RUNTIME_ELSE_ACTION,"CANCEL", "DAYSHIFT")
:SET &RETCOMMIT# = MODIFY_TASK(&RUNID#, COMMIT)
:SET &RETGO# = MODIFY_TASK(&RUNID#, GO)

Registerkarte "Externe Abhängigkeit"

Mit den folgenden Schlüsselwörtern können Sie die Einstellungen auf der Registerkarte Externe Abhängigkeiten einer externen Aufgabe in einem Workflow ändern.

  • EXTERNAL_SATISFACTION
    Definiert, wann das Ende einer externen Aufgabe erwartet wird

  • EXTERNAL_STATUS
    Setzt den erwarteten Status einer externen Aufgabe

  • EXTERNAL_ELSE_ACTION
    Definiert die Maßnahmen, die ergriffen werden müssen, wenn eine externe Aufgabe die Erwartungen nicht erfüllt

  • EXTERNAL_TIMEOUT_ACTION
    Definiert die Maßnahmen, die ergriffen werden müssen, wenn eine externe Aufgabe die vorgegebene Zeit überschreitet

Mehr Informationen:

Ausführungseinstellungen einer externen Abhängigkeit definieren

Verwenden Sie MODIFY_TASK mit EXTERNAL_SATISFACTION, um zu definieren, wie der Workflow eine externe Abhängigkeit handhabt. Der Workflow ist so konfiguriert, dass er erwartet, dass die externe Aufgabe zu einer bestimmten Zeit gestartet oder beendet wird, z. B. vor oder nach dem Start des aktuellen Workflows. EXTERNAL_SATISFACTION Lässt Sie die Einstellungen ändern, die die erwartete Vorlaufzeit bestimmen.

Syntax

MODIFY_TASK (RunID, [Aufgabenname], [Sequenznummer],EXTERNAL_SATISFACTION , Erfüllung der Vorlaufzeit [, Dauer])

Parameter

  • EXTERNAL_SATISFACTION
    Definiert die Erfüllung der Vorlaufzeit

  • Erfüllung der Vorlaufzeit
    Definiert, für wann angenommen wird, dass die externe Abhängigkeit die Erwartungen erfüllt:

    • LOGICAL_DATE
      Überprüft, ob die externe Aufgabe mit demselben logischen Datum aktiviert wurde wie der Workflow
    • LAST_EXECUTION
      Überprüft, ob das Ende der externen Aufgabe nach dem Ende der letzten Workflow-Durchführung liegt
    • BEFORE_START
      Überprüft, ob das Ende der externen Aufgabe innerhalb eines Zeitraumes vor dem Workflow-Start liegt
    • AFTER_START
      Überprüft, ob das Ende der externen Aufgabe nach dem aktuellen Workflow-Start liegt

  • Dauer
    (nur BEFORE_START) Zeitraum im Format HH:MM:SS
    Format: Script-Literal oder Script-Variable

Beispiel

Im folgenden Beispiel beginnt der Erfüllungszeitraum für die externe Abhängigkeit MM.GET.FILES mit dem Start des Workflows.

:SET &RUNID# = GET_UC_OBJECT_NR("MM.DAY")
:SET &RETSTOP# = MODIFY_TASK(&RUNID#, STOP_MODIFY)
:SET &RET# = MODIFY_TASK(&RUNID#, "MM.GET.FILES",, EXTERNAL_SATISFACTION, "AFTER_START")
:SET &RETCOMMIT# = MODIFY_TASK(&RUNID#, COMMIT)
:SET &RETGO# = MODIFY_TASK(&RUNID#, GO)

Setzen des erwarteten Status einer externen Abhängigkeit

Verwenden Sie MODIFY_TASK mit EXTERNAL_STATUS, um den erwarteten Status für eine externe Aufgabe festzulegen.

Syntax

MODIFY_TASK (RunID, [Aufgabenname], [Sequenznummer], EXTERNAL_STATUS , Status)

Parameter

  • EXTERNAL_STATUS
    Setzt oder entfernt den erwarteten Status einer externen Aufgabe

  • Status
    Erwarteter Status für die externe Aufgabe:

    • Endstatus
      Status wie z. B. ENDED_OK
    • NONE
      Das System prüft nur, ob die Aufgabe innerhalb des Erfüllungszeitraums beendet wurde, unabhängig vom Status

Beispiel

Im folgenden Beispiel erwartet der MM.DAY Workflow einen ENDED_OK-Status von der externen Aufgabe MM.GET.FILES.

:SET &RUNID# = GET_UC_OBJECT_NR("MM.DAY")
:SET &RETSTOP# = MODIFY_TASK(&RUNID#, STOP_MODIFY)
:SET &RET# = MODIFY_TASK(&RUNID#, "MM.GET.FILES",, EXTERNAL_STATUS, "ENDED_OK")
:SET &RETCOMMIT# = MODIFY_TASK(&RUNID#, COMMIT)
:SET &RETGO# = MODIFY_TASK(&RUNID#, GO)

Definition der Else-Aktion einer externen Abhängigkeit

Verwenden Sie MODIFY_TASK mit EXTERNAL_ELSE_ACTION, um die zu ergreifende Maßnahme zu definieren, wenn eine externe Aufgabe nicht den erwarteten Status erhält oder nicht innerhalb der erwarteten Zeit endet.

Syntax

MODIFY_TASK (RunID, [Aufgabenname], [Sequenznummer], EXTERNAL_ELSE_ACTION , WAIT|SKIP|CANCEL [, Alarmobjekt] )

Parameter

  • EXTERNAL_ELSE_ACTION
    Legt fest, dass Maßnahmen ergriffen werden sollen, wenn eine externe Aufgabe mindestens einmal den erwarteten Status nicht erhält oder nicht innerhalb der erwarteten Zeit endet

  • WAIT, SKIP oder CANCEL
    Definiert die zu ergreifende Maßnahme:

    • WAIT
      Wartet, bis die externe Aufgabe beendet ist
      Hinweis: Verwenden Sie MODIFY_TASK mit EXTERNAL_TIMEOUT_ACTION, um das Timeout für diese Aktion zu definieren.
    • SKIP
      Überspringt die externe Aufgabe
    • CANCEL
      Bricht den Workflow ab

  • Alarmobjekt
    (Optional) Name eines Benachrichtigungsobjekts mit dem Alarmtyp, das gestartet wird, wenn ein Timeout auftritt
    Format: Script-Literal oder Script-Variable

Beispiel

Im folgenden Beispiel wird der MM.DAY-Workflow abgebrochen, wenn die externe Aufgabe MM.GET.FILES nicht wie erwartet endet. Wenn das Script den Workflow abbricht, startet es ein Benachrichtigungsobjekt namens DAYSHIFT.

:SET &RUNID# = GET_UC_OBJECT_NR("MM.DAY")
:SET &RETSTOP# = MODIFY_TASK(&RUNID#, STOP_MODIFY)
:SET &RET# = MODIFY_TASK(&RUNID#, "MM.GET.FILES",, EXTERNAL_ELSE_ACTION, "CANCEL", "DAYSHIFT")
:SET &RETCOMMIT# = MODIFY_TASK(&RUNID#, COMMIT)
:SET &RETGO# = MODIFY_TASK(&RUNID#, GO)

Definition der Timeout-Einstellung einer externen Abhängigkeit

Verwenden Sie MODIFY_TASK mit EXTERNAL_TIMEOUT_ACTION, um die Timeout-Einstellung einer externen Aufgabe zu definieren, wenn Sie WAIT verwenden, und definieren Sie eine Else-Aktion.

Syntax

MODIFY_TASK (RunID, [Aufgabenname], [Sequenznummer], EXTERNAL_TIMEOUT_ACTION , Timeout-Länge, WAIT|SKIP|CANCEL[, Alarmobjekt])

Parameter

  • EXTERNAL_TIMEOUT_ACTION
    Legt die Wartezeit fest, wenn Sie eine Else-Aktion mit WAIT definieren

  • Timeout-Länge
    Timeout-Dauer im Format HH:MM:SS
    Format: Script-Literal oder Script-Variable

  • WAIT, SKIP oder CANCEL
    Definiert die zu ergreifende Maßnahme:

    • WAIT
      Wartet, bis die externe Aufgabe abgeschlossen ist
    • SKIP
      Überspringt die externe Aufgabe
    • CANCEL
      Bricht den Workflow ab

  • Alarmobjekt
    (Optional) Name eines Benachrichtigungsobjekts mit dem Alarmtyp, das gestartet wird, wenn ein Timeout auftritt
    Format: Script-Literal oder Script-Variable

Beispiel

Im folgenden Workflow besteht eine externe Abhängigkeit von einer Aufgabe mit dem Namen MM.GET.FILES. Der Workflow überspringt die externe Aufgabe, wenn die Aufgabe nicht wie erwartet innerhalb einer Stunde endet.

:SET &RUNID# = GET_UC_OBJECT_NR("MM.DAY")
:SET &RETSTOP# = MODIFY_TASK(&RUNID#, STOP_MODIFY)
:SET &RET# = MODIFY_TASK(&RUNID#, "MM.GET.FILES",, EXTERNAL_TIMEOUT_ACTION, "01:00:00", "SKIP")
:SET &RETCOMMIT# = MODIFY_TASK(&RUNID#, COMMIT)
:SET &RETGO# = MODIFY_TASK(&RUNID#, GO)

Ändert den Wert einer Variablen

Verwenden Sie MODIFY_TASK mit VALUE, um den Wert einer Variablen zu ändern, die auf der Registerkarte Variablen und Prompts gespeichert ist:

  • Objektvariable
    Einen vorhandenen Variablenwert ändern oder eine neue Variable mit einem bestimmten Wert erstellen.
  • PromptSet-Variable
    Ändern eines vorhandenen Variablenwerts eines PromptSet-Steuerelements.

Syntax

MODIFY_TASK (RunID, Aufgabenname, Sequenznummer, VALUE,PROMPTSET NAME|<VALUE>, VARIABLE|NEW VARIABLE, "VALUE", [SELECT|DESELECT|CLEAR|SPACE])

Parameter

  • VALUE
    Ändert den Wert einer Variablen:

    • Ändert den Wert einer vorhandenen Objektvariablen oder erstellt eine neue Objektvariable
    • Ändert den Wert einer vorhandenen PromptSet-Variablen

  • PromptSet-Name oder <VALUE>
    Gibt die Variable an:

    • PromptSet-Name
      Name des PromptSet-Objekts
    • <VALUE>
      Name der Objektvariablen

  • Variable
    (nur Objektvariablen) Name der neuen Variablen, wenn die Objektvariable noch nicht vorhanden ist
    Hinweis:: Schreiben Sie den Variablennamen ohne das vorangestellte kaufmännische Und

  • Wert
    (optional) Wert, der für die Variable festgelegt werden soll
    Hinweis: Sie müssen einen Wert festlegen, wenn Sie eine PromptSet-Variable ändern, bei der es sich um ein Array handelt.
    Format: Script-Literal oder Script-Variable

  • SELECT, DESELECT, CLEAR oder SPACE
    (Optional) Ändert die in der Variablen ausgewählten Werte:

    • SELECT
      (Nur PromptSet-Variablen-Arrays) Wählt Zeilen eines Arrays aus
    • DESELECT
      (Nur PromptSet-Variablen-Arrays) Hebt die Auswahl für die Zeilen eines Arrays auf
    • CLEAR
      (Nur PromptSet-Variablen-Arrays) Hebt die Auswahl aller Zeilen eines Arrays auf
    • SPACE (Standard)
      Ändert den Wert der PromptSet-Variablen oder Objektvariablen in leeren Text
    Hinweis: Mit diesen Schlüsselwörtern können Sie Werte auswählen oder ihre Auswahl aufheben, wenn die Variable mehrere Werte zulässt. Verwenden Sie diese Parameter, um Werte aus PromptSet-Steuerelementen zu verwalten, wie beispielsweise Kontrollkästchen. Bei den ausgewählten Werten kann es sich um benutzerselektierte Werte, Standardwerte oder Werte handeln, die für den Workflow definiert wurden.

Beispiele

Im folgenden Beispiel aktiviert das Script einen Workflow und stoppt den Workflow bei Änderungen. Das Script erstellt eine Variable und weist der Variablen einen Wert zu.

: SET &RUNID# = ACTIVATE_UC_OBJECT (" JOBP.NEW.01 ")
: SET &RETSTOP# = MODIFY_TASK (&RUNID#, STOP_MODIFY)
: SET &MODIFY# = MODIFY_TASK (&RUNID#, " SCRI.NEW.01 ", 4, VALUE, "<VALUE>", "&&VARIABLE#", " Wien ")
: SET &RETCOMMIT# = MODIFY_TASK(&RUNID#, COMMIT)
: SET &RETGO# = MODIFY_TASK (&RUNID#, GO)

Im folgenden Beispiel hat ein Script-Objekt ein zugewiesenes PromptSet. Das Script ändert die Werte der PromptSet-Variablen CKG#, d. h. ein Array von Werten aus einem Checklisten-Steuerelement. Die Parameter in MODIFY_TASK, VALUE wählen den Wert Test01 aus der PromptSet -Variablen aus.

:SET &RUNID# = ACTIVATE_UC_OBJECT("JOBP.NEW.01")
:SET &RETSTOP# = MODIFY_TASK(&RUNID#, STOP_MODIFY)
:SET &MODIFY# = MODIFY_TASK(&RUNID#, "SCRI.NEW.01", 4, VALUE, "PRPT.NEW.01", "CKG#", "Test01", SELECT)
:SET &RETCOMMIT# = MODIFY_TASK(&RUNID#, COMMIT)
:SET &RETGO# = MODIFY_TASK(&RUNID#, GO)

Im folgenden Beispiel wird der Wert der PromptSet-Variablen Textfield01# auf mytextfieldvalue gesetzt.

:SET &RUNID# = ACTIVATE_UC_OBJECT("JOBP.NEW.01")
:SET &RETSTOP# = MODIFY_TASK(&RUNID#, STOP_MODIFY)
:SET &MODIFY# = MODIFY_TASK(&RUNID#, "SCRI.NEW.01", 4, VALUE, "PRPT.NEW.01", "Textfield01#", "mytexfieldvalue")
:SET &RETCOMMIT# = MODIFY_TASK(&RUNID#, COMMIT)
:SET &RETGO# = MODIFY_TASK(&RUNID#, GO)

Siehe auch:

seealso

Script-Elemente für die Handhabung von Aufgaben