PREP_PROCESS_COMMENTS

Verwenden Sie die Script-Funktion PREP_PROCESS_COMMENTS, um den Zeitstempel, Anwender und Text eines Aufgabenkommentars abzurufen. Das Script ermöglicht es Ihnen, nach einem bestimmten Text im Kommentar zu filtern. Die Script-Funktion gibt einen Verweis auf eine Datensequenz zurück, die Sie zur weiteren Verarbeitung verwenden können, indem Sie den Rückgabewert der Script-Anweisung :PROCESS zuweisen. Verwenden Sie die Script-Funktion GET_PROCESS_LINE, um auf jeden Kommentar in der Aufgabe zuzugreifen.

Hinweise:

• Der Script-Variablen, die die Datensequenz-Referenz enthält, kann kein neuer Wert zugewiesen werden. Verwenden Sie :CLOSE_PROCESS, um die vorhandene Datensequenz zu verwerfen und einen neuen Wert zuzuweisen.
• Es gibt keine Fehlermeldung, wenn der von Ihnen gesuchte Kommentar nicht die Werte enthält, die Sie angeben. Die Script-Anweisung :PROCESS verarbeitet die Datensequenz in diesem Fall nicht.

Mehr Informationen:

• Kommentare hinzufügen
• :PROCESS... :TERM_PROCESS... :ENDPROCESS
• GET_PROCESS_LINE

Syntax

PREP_PROCESS_COMMENTS ([RunID] [,Text] [, Benutzer])

Parameter

• PREP_PROCESS_COMMENTS
  Ruft Text und Details eines Aufgabenkommentars ab

• RunID
  (Optional) RunID der Aufgabe, deren Kommentare Sie abrufen wollen
  Wenn Sie keine RunID angeben, werden die Kommentare der Aufgabe gelesen, die die Script-Funktion aufruft.
  Format: Script-Literal, Script-Variable oder Zahl

• Text
  (Optional) Filtert nach einem bestimmten Text im Kommentar
  Format: Script-Literal oder Script-Variable
  Maximale Zeichenanzahl: 200
  Standardwert: *

• Benutzer
  (Optional) Filtert nach Kommentaren, die von einem bestimmten Benutzer hinzugefügt werden
  Geben Sie den Namen des Benutzerobjekts (NAME/ABTEILUNG) an.
  Format: Script-Literal oder Script-Variable
  Maximale Zeichenanzahl: 200
  Standardwert: *

Hinweise:

• Bei Filtern wird die Groß-/Kleinschreibung beachtet.
• Verwenden Sie das Platzhalterzeichen *, das für eine beliebige Anzahl von Zeichen steht, oder ? für ein einzelnes Zeichen in einem Filter.
• Wenn Sie einen leeren String für einen Filter angeben, gibt die Script-Funktion alle Werte zurück.
• Fügen Sie beide Kommas in die Parameter ein, wenn Sie nur einen Benutzer angeben, jedoch keinen RunID- oder Textfilter.

Beispiele

Eine Aufgabe wurde gestartet und enthält die folgenden Kommentare:

• Benutzer: SMITH/VIE
  Zeit: 20.05.2018 22:20
  Kommentar: FileTransfer erfolgreich gestartet

• Benutzer: BROWN/VIE
  Zeit: 31.08.2018 11:22
  Kommentar: Datei konnte aufgrund eines Schreibfehlers nicht gefunden werden. Korrigiert.

• Benutzer: SMITH/VIE
  Zeit: 01.10.2018 16:25
  Kommentar: FileTransfer wurde abgebrochen. Datei konnte nicht gefunden werden. Frau Brown wurde informiert.

Das folgende Script ruft alle Kommentare in der Aufgabe ab und gibt den Benutzer und den Text der Kommentare im Aktivierungsreport aus.

:SET &HND# = PREP_PROCESS_COMMENTS()

:PROCESS &HND#
:   SET &USER# = GET_PROCESS_LINE(&HND#,2)
:   SET &TEXT# = GET_PROCESS_LINE(&HND#,3)
:   PRINT "&USER#:  &TEXT#"
:ENDPROCESS

:CLOSE_PROCESS &HND#

Das folgende Script ruft nur die Kommentare ab, die vom Benutzer SMITH erstellt wurden, und gibt sie im Aktivierungsreport einschließlich des Zeitstempels aus.

:SET &HND# = PREP_PROCESS_COMMENTS(,,"SMITH/VIE")

:PROCESS &HND#
:   SET  &TIME# = GET_PROCESS_LINE(&HND#,1)
:   SET &TEXT# = GET_PROCESS_LINE(&HND#,3)
:   PRINT "&TIME#:  &TEXT#"
:ENDPROCESS

:CLOSE_PROCESS &HND#

Das folgende Beispiel zeigt ein Script, das von einer anderen Aufgabe aufgerufen wird. Das Script ruft die RunID der Aufgabe ab, die die Kommentare enthält, und verwendet die RunID, um alle Kommentare in der Aufgabe abzurufen, die das Wort "Error" enthalten.

:SET &RunID = GET_UC_OBJECT_NR(MM.RETRIEVE.FILES)

:SET &HND# = PREP_PROCESS_COMMENTS(&RunID,"*error*")

:PROCESS &HND#
:   SET &TEXT# = GET_PROCESS_LINE(&HND#,3)
:   PRINT "Comment: &TEXT#"
:ENDPROCESS

:CLOSE_PROCESS &HND#

Siehe auch: