:SEND_SNMP_TRAP

Instruction de script : Envoie une trap SNMP

Syntaxe

:SEND_SNMP_TRAP Trap Code, Parameter[, Parameter[, Parameter]]...

Syntaxe	Description / format
Trao code	Code d'interruption définissable librement auquel la gestion SNMP peut réagir. Format : nombre, variable de script ou fonction de script
Parameter	Informations supplémentaires qui peuvent être envoyées avec le trap SNMP Format : nombre, littéral de script, variable de script ou fonction de script Le numéro de client doit être indiqué entre guillemets (ex. : "1000")

L'instruction de script envoie une trap SNMP avec les paramètres spécifiés à un système de gestion. Elle ne peut être utilisée qu'une fois tous les prérequis de la fonctionnalité SNMP implémentés.

Au maximum, 10 paramètres peuvent être joints. 5 chaînes de caractères et 5 nombres au maximum sont autorisés. La position des chaînes de caractères et des nombres est prédéfinie. D'abord viennent les chaînes de caractères, suivies des nombres. Au moins une chaîne de caractères doit être indiquée.

Les codes de trap générés par AE et HP OpenView Integrator (codes trap : 10000 - 10010) ne doivent pas être utilisés.

Exemples

Le premier exemple montre un test simple. La trap SNMP 50000 envoie tous les paramètres possibles au système de gestion.

:SEND_SNMP_TRAP 50000,"Text1","TEXT2","TEXT3","TEXT4","TEXT5",1,2,3,4,5

Dans le deuxième exemple, chaque date d'activation est ensuite transmise. Différentes interruptions sont envoyées selon qu'il s'agit d'une activation directe ou d'une activation dans un Workflow. Les deux traps se composent d'un code trap et d'une chaîne de caractères préformatée.

:SET &NAME#     = SYS_ACT_ME_NAME()
:SET &ID#       = SYS_ACT_ME_NR()
:SET &JPNAME#   = SYS_ACT_PARENT_NAME()
:SET &CLIENT#   = SYS_ACT_CLIENT()
!Trap type = Alarm
:SET &TYPE#     = 4
!Importance of the event
:SET &SEV#      = 4


:IF  "&JPNAME#" = ""
:    SEND_SNMP_TRAP 50001, "&CLIENT#","Error in task &NAME# (&ID#)!",,,,&TYPE#,&SEV#
:ELSE
:    SET &JPID# = SYS_ACT_PARENT_NR()
:    SEND_SNMP_TRAP 50002, "&CLIENT#","Error in workflow &JPNAME# (&JPID#) in the task &NAME# (&ID#m)!",,,,&TYPE#,&SEV#
:ENDIF

Le troisième exemple montre comment les dates d'activation récupérées sont transmises à l'instruction de script en tant que paramètres uniques. Les dates d'activation sont ainsi disponibles dans le système de gestion en tant que valeurs uniques et peuvent ensuite y être traitées plus facilement.

:SET &NAME#     = SYS_ACT_ME_NAME()
:SET &ID#       = SYS_ACT_ME_NR()
:SET &JPNAME#   = SYS_ACT_PARENT_NAME()
:SET &CLIENT#   = SYS_ACT_CLIENT()
!Trap type = Alarm
:SET &TYPE#     = 4
!Importance of the event
:SET &SEV#      = 4



:IF   &JPNAME# = ""
:    SEND_SNMP_TRAP 50001,"&CLIENT#","&NAME#",,"Error in the task!",,&TYPE#,&SEV#,&ID#
:ELSE
:    SET &JPID = SYS_ACT_PARENT_NR()
:    SEND_SNMP_TRAP 50002,"&CLIENT#","&NAME#","&JPNAME#","Error in the workflow!",,&TYPE#,&SEV#,&ID#,&JPID#
:ENDIF

Si &ID# et/ou &JPID# sont envoyés en tant que chiffres et non en tant que chaînes de caractères, ils peuvent être transmis uniquement à partir du sixième paramètre. Des virgules doivent remplacer les paramètres omis qui sont prévus pour des chaînes de caractères.

Voir aussi :