Benachrichtigung - Monitor

Benachrichtigung

Benachrichtigungs-Attribute

---

Benachrichtigung - Objekttyp ALARM

Das Objekt CALL.ALARM ist eine vorgefertigte Benachrichtigung, welche durch ein Script bestimmte Daten in den Meldungstext schreibt.

Allgemeine Informationen

Beim Anlegen eines neuen Benachrichtigung-Objektes kann man zwischen 2 verschiedenen Typen wählen: STANDARD und ALARM.

Beide Objekte sind Benachrichtigungen und unterscheiden sich daher nicht durch erweiterte Einstellungsmöglichkeiten. Die Benachrichtigung vom Typ ALARM besitzt jedoch ein vorgefertigtes AE Script, welches verschiedene Daten liest und im Meldungstext ausgibt. Zusätzlich wird als Empfänger automatisch der Benutzer eingetragen, der das Objekt ausführt. ALARM-Benachrichtigungen werden immer mit dem Typ "Alarm" und Priorität "Hoch" angelegt.

Script

Das fertige AE Script ermöglicht eine sofortige Ausführung des CALL.ALARM Objektes nach dem Anlegen, da als Empfänger automatisch der Benutzer, der das Benachrichtigungs-Objekt gestartet hat, eingetragen wird. Zusätzlich werden dynamische Werte wie Name der verursachenden Aufgabe, deren RunID, usw. ermittelt und im Meldungstext ausgegeben. Das Script gibt den Meldungstext in der passenden Sprache aus.

Beispiele:

Ermittlung des Benutzers, der das Objekt gestartet hat, und der zugehörigen Abteilung.
Mit :ADD_ATT wird dieser Benutzer als Empfänger aufgenommen. Daher kann man CALL.ALARM Objekte auch ausführen, ohne vorher manuell einen Empfänger einzutragen.

!Get Operator
:set &userid# = SYS_USER_NAME
:set &dep# = SYS_USER_DEP
:ADD_ATT OPERATOR, '&userid#/&dep#'
!

Ermittlung von Name, RunID, Status und Returncode der Aufgabe, durch die das Benachrichtigungs-Objekt aufgerufen wurde. Zusätzliche Informationen dazu finden Sie hier: Benachrichtigung - Ausführen.

!Get Script
:read &UC_CAUSE_NAME,,
:read &UC_CAUSE_NR,,
:read &UC_CAUSE_STATE,,
:read &UC_CAUSE_RETCODE,,
!
:set &nl# = UC_CRLF
!

Ermittlung des Namen, RunID und Objekttyp der übergeordneten Aufgabe, die das Benachrichtigungs-Objekt aktiviert hat. Zusätzlich wird der Name des Automation Engine Systems, die Mandantennummer, Uhrzeit + Datum der Aktivierung und die Sprache abgefragt. Das Scriptsprachmittel GET_MSG_TEXT() liefert den Statustext der Aufgabe, durch die die Benachrichtigung gestartet wurde.

:set &parentname# = SYS_ACT_PARENT_NAME('ACT')
:set &parentnr# = SYS_ACT_PARENT_NR('ACT')
:set &parenttyp# = SYS_ACT_PARENT_TYP('ACT')
:set &system# = GET_UC_SYSTEM_NAME
:set &client# = SYS_ACT_CLIENT
:set &date# = SYS_DATE_PHYSICAL()
:set &time# = SYS_TIME_PHYSICAL("HH:MM:SS")
:set &lang# = SYS_USER_LANGUAGE
:set &statustext# = get_msg_txt(&UC_CAUSE_STATE,'')
!

Nach Überprüfung der Sprache, werden die oben ermittelten Informationen mit Hilfe der Scriptsprachmittel :PUT_ATT bzw. :PUT_ATT_APPEND in Deutsch, Englisch oder Französisch in den Meldungstext geschrieben.

:if &lang# = 'E'
!: put_att SUBJECT = "Alarm:'&UC_CAUSE_NAME' RunID:'&UC_CAUSE_NR' Client:'&client#'
: set &date# = conv_date(&date#,"MM/DD/YYYY")
: PUT_ATT CALL_TEXT = "An error occurred! &nl# &nl#"
: put_att_append CALL_TEXT = "AE system: &system# &nl#"
: put_att_append CALL_TEXT = "Client: &client# &nl#"
: put_att_append CALL_TEXT = "Object: &UC_CAUSE_NAME &nl#"
: put_att_append CALL_TEXT = "Run#: &UC_CAUSE_NR &nl#"
: put_att_append CALL_TEXT = "State Text: &statustext# (&UC_CAUSE_STATE) &nl#"
: put_att_append CALL_TEXT = "Retcode: &UC_CAUSE_RETCODE &nl#"
: put_att_append CALL_TEXT = "Date/Time: &date# &time# &nl# &nl#"
: put_att_append CALL_TEXT = "Parent of this object (if available): &nl# &nl#"
: put_att_append CALL_TEXT = "Parent: &parentname# &nl#"
: put_att_append CALL_TEXT = "Type: &parenttyp# &nl#"
: put_att_append CALL_TEXT = "Run#: &parentnr# &nl#"
:endif

:if &lang# = 'D'
!: put_att SUBJECT = "Alarm:'&UC_CAUSE_NAME' RunID:'&UC_CAUSE_NR' Client:'&client#' 
: set &date# = conv_date(&date#,"MM/DD/YYYY")
: PUT_ATT CALL_TEXT = "Ein Fehler ist aufgetreten! &nl# &nl#"
: put_att_append CALL_TEXT = "AE system: &system# &nl#"
: put_att_append CALL_TEXT = "Mandant: &client# &nl#"
: put_att_append CALL_TEXT = "Objekt: &UC_CAUSE_NAME &nl#"
: put_att_append CALL_TEXT = "Run#: &UC_CAUSE_NR &nl#"
: put_att_append CALL_TEXT = "Status: &statustext# (&UC_CAUSE_STATE) &nl#"
: put_att_append CALL_TEXT = "Retcode: &UC_CAUSE_RETCODE &nl#"
: put_att_append CALL_TEXT = "Datum/Zeit: &date# &time# &nl# &nl#"
: put_att_append CALL_TEXT = "Parent dieses Objektes (wenn vorhanden): &nl# &nl#"
: put_att_append CALL_TEXT = "Parent: &parentname# &nl#"
: put_att_append CALL_TEXT = "Typ: &parenttyp# &nl#"
: put_att_append CALL_TEXT = "Run#: &parentnr# &nl#"
:endif

:if &lang# = 'F'
!: put_att SUBJECT = "Alarm:'&UC_CAUSE_NAME' RunID:'&UC_CAUSE_NR' Client:'&client#'
: set &date# = conv_date(&date#,"MM/DD/YYYY")
: PUT_ATT CALL_TEXT = "Une erreur s'est produite! &nl# &nl#"
: put_att_append CALL_TEXT = "AE system: &system# &nl#"
: put_att_append CALL_TEXT = "Client: &client# &nl#"
: put_att_append CALL_TEXT = "Objet: &UC_CAUSE_NAME &nl#"
: put_att_append CALL_TEXT = "Run#: &UC_CAUSE_NR &nl#"
: put_att_append CALL_TEXT = "Statut: &statustext# (&UC_CAUSE_STATE) &nl#"
: put_att_append CALL_TEXT = "Retcode: &UC_CAUSE_RETCODE &nl#"
: put_att_append CALL_TEXT = "Date/Heure: &date# &time# &nl# &nl#"
: put_att_append CALL_TEXT = "Parent de cet objet (si disponible): &nl# &nl#"
: put_att_append CALL_TEXT = "Parent: &parentname# &nl#"
: put_att_append CALL_TEXT = "Type: &parenttyp# &nl#"
: put_att_append CALL_TEXT = "Run#: &parentnr# &nl#"
:endif

Siehe auch:

Erste Schritte - Benachrichtigungen
Benachrichtigung - Ausführen