MODIFY_TASK

Mit der Script-Funktion MODIFY_TASK können Sie aktive Workflows und Aufgaben in aktiven Workflows ändern. Mit MODIFY_TASK können Sie die Aufgabeneigenschaften für einen bestimmten Workflow ändern, ohne die Objektdefinitionen zu bearbeiten. Die Aufgabeneigenschaften im Workflow überschreiben die Einstellungen in der Objektdefinition. Weitere Informationen finden Sie unter Aufgabeneigenschaften in Workflows.

Überblick

Vor und nach Änderungen mit MODIFY_TASK, müssen Sie den Workflow-Status immer mit vorläufigen MODIFY_TASK-Script-Zeilen ändern. Befolgen Sie diese Reihenfolge, wenn Sie einen Workflow mit MODIFY_TASK ändern:

1. Verwenden Sie MODIFY_TASK mit dem STOP_MODIFY-Parameter, um den Workflow zu stoppen und die Bearbeitung zu ermöglichen.
2. Verwenden Sie MODIFY_TASK mit anderen Parametern, um eine oder mehrere Änderungen am Workflow vorzunehmen.
3. Verwenden Sie MODIFY_TASK mit dem Parameter COMMIT, um Ihre Änderungen zu aktivieren.
4. Verwenden Sie MODIFY_TASK mit dem GO-Parameter, um den Workflow zu starten.

Syntax und Parameter

Die Grundsyntax dieser Script-Funktion enthält die folgenden Elemente:

MODIFY_TASK (RunID, parameters, KEYWORD)

Wobei:

• MODIFY_TASK
  
  Ändert einen aktiven Workflow
• RunID
  RunID des aktiven Workflows, der geändert werden soll
• parameters
  Ein oder mehrere Parameter geben an, welche Aufgabe geändert werden soll, oder andere Parameter je nach Änderung
  
• KEYWORD
  Gibt die zu ergreifende Maßnahme an
  Alle verfügbaren Schlüsselwörter werden in diesem Thema beschrieben.
  Hinweis: Einige Schlüsselwörter haben zusätzliche Parameter nach dem Schlüsselwort.

Wichtig!

• Sie müssen die Parameter von MODIFY_TASK in der Reihenfolge schreiben, in der sie in den Syntaxbeispielen in diesem Thema angezeigt werden.
• Sie müssen Kommas verwenden, wie in den Syntaxbeispielen gezeigt, auch wenn Sie einzelne Parameter weglassen.

Mehrere Änderungen, die Sie mit MODIFY_TASK durchführen können, erfordern, dass Sie eine bestimmte Aufgabe angeben. Verwenden Sie einen oder beide der folgenden Parameter, um die Aufgabe anzugeben:

• task name
  Name der Aufgabe
  Hinweis: Verwenden Sie START oder END, wenn Sie das Start- oder Endfeld eines Workflows ändern möchten.
  Format: Script-Literal, Zahl oder Script-Variable.
  
• sequence number
  Sequenznummer der Aufgabe
  Die Sequenznummer bezieht sich auf die Nummer innerhalb des Workflows, z.B. 3 für die dritte Aufgabe. Die Sequenznummer wird in dem Aufgabenfeld des Workflow-Editors angezeigt. Die Sequenznummer ist nicht die RunID. Weitere Informationen finden Sie unter Aufgabenkästchen.
  Format: Script-Literal, Zahl oder Script-Variable.
  

Hinweise:

• Wenn Sie sowohl den Aufgabennamen als auch die Sequenznummer angeben, stellen Sie sicher, dass diese mit der gleichen Aufgabe übereinstimmen.
• Wenn es im Workflow mehrere Aufgaben mit gleichem Namen gibt und Sie keine Sequenznummer angeben, verwendet das System die Aufgabe mit der niedrigsten Nummer.

Beispielszenario

Sie möchten Aufgaben zu einem Workflow hinzufügen, wenn der Workflow aktiv ist. Dieses Beispiel zeigt, wie man MODIFY_TASK-Funktionen mit mehreren verschiedenen Schlüsselwörtern kombiniert, um die Aufgaben hinzuzufügen und zu platzieren und die erforderlichen Abhängigkeiten zu erstellen.

Vorbedingungen:

• Workflow-Objekt
  Für die Zwecke dieses Beispiels hat der Workflow derzeit eine Unteraufgabe.
• Zwei ausführbare Objekte (Aufgabe.01 und Aufgabe.02)

Ziele:

• Beide Aufgaben sind abhängig von ihren Vorgängern im Workflow:
  • Aufgabe.01 beginnt direkt beim Start des Workflows.
  • Aufgabe.02 startet nach Beendigung von Aufgabe.01.
• Der Workflow endet mit dem Ende der Aufgabe.02.

Schreiben Sie das folgende Script auf der Skript-Seite der Unteraufgabe, die sich gerade im Workflow befindet.

Syntax

:SET &RUNID# = SYS_ACT_PARENT_NR(ACT)

:PRINT &RUNID#

:SET &RET# = MODIFY_TASK(&RUNID#, STOP_MODIFY)

:SET &RET# = MODIFY_TASK(&RUNID#, 'TASK.01', ,ADD_TASK)

:SET &RET# = MODIFY_TASK(&RUNID#, 'TASK.01', ,MOVE_TASK, 2, 3)

:SET &RET# = MODIFY_TASK(&RUNID#, 'TASK.01', ,ADD_DEPENDENCY, 'START', , 'NONE' )

 

:SET &RET# = MODIFY_TASK(&RUNID#, 'TASK.02', ,ADD_TASK)

:SET &RET# = MODIFY_TASK(&RUNID#, 'TASK.02', ,MOVE_TASK, 3, 3)

:SET &RET# = MODIFY_TASK(&RUNID#, 'TASK.02', ,ADD_DEPENDENCY, 'TASK.01', , 'NONE' )

 

:SET &RET# = MODIFY_TASK(&RUNID#, 'END', ,ADD_DEPENDENCY, 'TASK.02', , 'NONE' )

:SET &RET# = MODIFY_TASK(&RUNID#, 'END', ,REMOVE_DEPENDENCY, 'START', , 'NONE' )

:SET &RET# = MODIFY_TASK(&RUNID#, COMMIT)

:SET &RET# = MODIFY_TASK(&RUNID#, GO, FORCED)

Parameter

• SYS_ACT_PARENT_NR
  Ermittelt die RunID des Workflows, in dem sich die Aufgabe befindet
• PRINT
  Druckt die abgerufene RunID im Aktivierungsreport
  
• MODIFY_TASK
  Führt eine Änderung am Workflow oder an einer Aufgabe im Workflow durch
• STOP_MODIFY
  Stoppt den Workflow für Änderungszwecke
• ADD_TASK
  Fügt dem Workflow eine Aufgabe hinzu
• MOVE_TASK
  Verschiebt die hinzugefügte Aufgabe an die gewünschte Stelle (gekennzeichnet durch Spalte und Zeile) im Workflow
• ADD_DEPENDENCY
  Zeichnet eine Zeile zum Vorgänger der hinzugefügten Aufgabe, um eine Abhängigkeit zu erstellen
• REMOVE_DEPENDENCY
  Löscht die Zeile zu einer Vorgängeraufgabe, um die Abhängigkeit zu entfernen
• COMMIT
  Übernimmt die Änderungen am Workflow
• GO, FORCED
  Startet den Workflow wieder, auch wenn ein anderer Benutzer ihn zur Bearbeitung geöffnet hat

Rückgabewerte

MODIFY_TASKhat je nach Art der Änderung folgende Rückgabewerte.

• 0
  
  Die Änderung war erfolgreich
• 9
  
  Sie sind nicht berechtigt, die angegebene Aufgabe zur Laufzeit zu ändern
• 20591
  
  Ein Workflow mit dieser RunID existiert nicht oder ist nicht mehr aktiv
• 20738
  
  Die Aufgabe befindet sich in einem Zustand, in dem Änderungen nicht möglich sind
• 20739
  
  Die Aufgabe kann nicht geändert werden, da sie von einem anderen Benutzer geändert wird
• 20740
  
  Der von Ihnen angegebene Objekttyp ist ungültig
• 20741
  
  Es gibt keine Aufgabe mit dem angegebenen Namen und/oder der RunID
• 20742
  
  Der angegebene Aufgabenname und die RunID passen nicht zur gleichen Aufgabe
• 20743
  
  Die Aufgabe kann nicht geändert werden, da der entsprechende Workflow nicht zur Bearbeitung gestoppt wurde
• 20744
  
  Die Aufgabe kann nicht geändert werden, da sie sich in einem unveränderlichen Zustand befindet
• 20745
  
  Die Aufgabe kann nicht geändert werden, da der Wert nicht erlaubt ist
• 20746
  
  Die Abhängigkeit kann nicht hinzugefügt werden, da sie bereits existiert
• 20747
  
  Die Abhängigkeit kann nicht geändert werden, da sie sich in einem unveränderlichen Zustand befindet
• 20748
  
  Die Aufgabe kann nicht hinzugefügt werden, da diese Position bereits von einer anderen Aufgabe besetzt ist
• 20749
  
  Der Objekttyp der angegebenen Aufgabe ist ungültig
• 20750
  
  Die Funktion kann für diese Aufgabe mit der jeweiligen RunID aufgrund eines früheren Fehlers nicht verarbeitet werden
• 20752
  
  Sie können externe Aufgaben nur durch externe Aufgaben ersetzen
• 20753
  
  Sie können <START> oder <END> nicht ersetzen
• 20754
  
  <START> kann keinen Vorgänger haben
• 20755
  
  <END> kann keinen Nachfolger haben
• 20756
  
  Externe Aufgaben können keinen Vorgänger haben
• 20757
  
  Die Aufgabe, die Sie für die Änderung einer externen Abhängigkeit angegeben haben, ist ungültig
• 20758
  
  Externe Abhängigkeiten können nicht angezeigt werden

MODIFY_TASK, ADD_TASK hat die folgenden Rückgabewerte:

• Laufende Nummer der Aufgabe, die Sie dem Workflow hinzugefügt haben
• 0 - die Aufgabe konnte nicht hinzugefügt werden

MODIFY_TASK, REPLACE_TASK und MODIFY_TASK,CLONE_AND_REPLACE_TASK haben die folgenden Rückgabewerte:

• Laufende Nummer der Aufgabe, die Sie dem Workflow hinzugefügt haben
• 0 - die Aufgabe konnte nicht ersetzt werden

Stoppen, Bestätigen von Änderungen und Starten des Workflows

Verwenden Sie MODIFY_TASK mit Statusparametern, um den Workflow zu stoppen, Ihre Änderungen vorzunehmen und zu übertragen und den Workflow erneut zu starten. Sie müssen den Workflow stoppen und starten, um die anderen in diesem Thema beschriebenen MODIFY_TASK-Parameter zu verwenden.

Syntax

MODIFY_TASK (RunID, status [, FORCED])

Parameter

• status
  Zu setzender Status für den Workflow
  Format: AE-Name, Script-Literal oder Script-Variable
  Erlaubte Werte:
  • COMMIT
    Aktiviert Änderungen, ohne den Workflow zu starten
  • GO
    Startet einen gestoppten Workflow
    Verwenden Sie den Parameter FORCED, um einen Workflow zu starten, auch wenn sein Monitor zur Bearbeitung geöffnet ist
  • STOP
    Stoppt einen Workflow
  • STOP_MODIFY
    Stoppt den Workflow für Änderungszwecke
• FORCED
  (Optional) Startet einen gestoppten Workflow, auch wenn der Workflow-Monitor zur Bearbeitung geöffnet ist
  Verwenden Sie dieses Schlüsselwort in Kombination mit dem GO-Status.
  Wichtig! Änderungen, die von einem anderen Benutzer vorgenommen werden, gehen verloren, wenn Sie den Workflow während der Bearbeitung stoppen.

Hinweise:

• Sie können nur andere Workflows stoppen und starten, aber nicht den Workflow, in dem sich das Script selbst befindet.
• Sie können MODIFY_TASK nicht verwenden, um den Workflow zu bearbeiten, in dem sich das Script befindet.

Beispiele

Das folgende Beispiel stoppt den MM.DAY-Workflow und ermöglicht es Ihnen, Änderungen vorzunehmen.

:SET &RUNID# = GET_UC_OBJECT_NR("MM.DAY")
:SET &RET# = MODIFY_TASK(&RUNID#, STOP_MODIFY)

Das folgende Beispiel startet den MM.DAY Workflow, auch wenn ein anderer Benutzer den Workflow bearbeitet.

:SET &RUNID# = GET_UC_OBJECT_NR("MM.DAY")
:SET &RET# = MODIFY_TASK(&RUNID#, GO, FORCED)

Workflow-Inhalte ändern

Mit den folgenden Schlüsselwörtern können Sie den Inhalt eines aktiven Workflows ändern:

• ADD_TASK
  Eine Aufgabe im Workflow hinzufügen
• REPLACE_TASK bzw. CLONE_AND_REPLACE
  Eine Aufgabe im Workflow ersetzen
• MOVE_TASK
  Verschiebt eine Aufgabe im Workflow an eine andere Position innerhalb des Workflows
• ACTIVE
  Aktiviert oder deaktiviert eine Workflow-Aufgabe

Eine Aufgabe oder externe Abhängigkeit hinzufügen

Verwenden Sie MODIFY_TASK mit ADD_TASK, um eine Aufgabe zu einem aktiven Workflow hinzuzufügen. Verwenden Sie das Schlüsselwort EXTERNAL, um eine Aufgabe als externe Abhängigkeit hinzuzufügen.

Die Aufgabe, die Sie hinzufügen, ist nicht automatisch mit anderen Aufgaben verknüpft. Verwenden Sie MODIFY_TASK mit ADD_DEPENDENCY, um die gewünschten Zeilen zu erstellen. Verwenden Sie MODIFY_TASK mit MOVE_TASK, um die Aufgabe an die richtige Stelle im Workflow zu bringen.

Syntax

MODIFY_TASK (RunID, object name ,, ADD_TASK [, EXTERNAL [, Workflow name]] )

Parameter

• object name
  Name des Objekts, das in den Workflow eingefügt werden soll
  Format: Script-Literal, Zahl oder Script-Variable
  
• ADD_TASK
  Fügt die Aufgabe hinzu.
• EXTERNAL
  (Optional) Fügt die Aufgabe als externe Abhängigkeit hinzu
• Workflow name
  (Optional) Name des Workflows, auf den sich die externe Abhängigkeit bezieht
  Format: Script-Literal oder Script-Variable
  

Hinweise:

• Schreiben Sie 2 Kommas nach dem Parameter object name. Dieser dritte Parameter ist die Sequenznummer einer Aufgabe innerhalb des Workflows. Er hat jedoch für das Hinzufügen einer Aufgabe keine Bedeutung.
• Wenn der Workflow so konfiguriert ist, dass Aufgaben die Priorität AE des Workflows erben, dann bekommt die Aufgabe, die Sie hinzufügen, auch diese Priorität.

Tipp: Verwenden Sie die Sequenznummer, die die Funktion zurückgibt, um die Aufgabe anzugeben, wenn Sie andere Änderungen an der hinzugefügten Aufgabe vornehmen.

Beispiel

Das folgende Beispiel fügt dem Workflow MM.DAY das Objekt FILE.INPUT hinzu.

:SET &RUNID# = GET_UC_OBJECT_NR("MM.DAY")
:SET &RETSTOP# = MODIFY_TASK(&RUNID#, STOP_MODIFY)
:SET &RET# = MODIFY_TASK(&RUNID#,"FILE.INPUT",, ADD_TASK)
:SET &RETCOMMIT# = MODIFY_TASK(&RUNID#, COMMIT)
:SET &RETGO# = MODIFY_TASK(&RUNID#, GO)

Aufgabe in einem Workflow ersetzen

Verwenden Sie MODIFY_TASK mit REPLACE_TASK oder CLONE_AND_REPLACE, um eine bestimmte Aufgabe im Workflow durch ein anderes Objekt zu ersetzen. Sie können eine externe Abhängigkeit nur durch eine externe Abhängigkeit und eine normale Workflow-Aufgabe durch eine normale Workflow-Aufgabe ersetzen.

Syntax

MODIFY_TASK (RunID, [task name], [sequence number], REPLACE_TASK|CLONE_AND_REPLACE , object name [, EXTERNAL [, Workflow name]])

Parameter

• REPLACE_TASK bzw. CLONE_AND_REPLACE
  Ersetzt die Aufgabe durch das von Ihnen angegebene Objekt
  • REPLACE_TASK 
    Setzt den Status der alten, ersetzten Aufgabe auf inaktiv
  • CLONE_AND_REPLACE
    Hält die alte Aufgabe aktiv
• object name
  Name des Objekts, das die Aufgabe ersetzen soll
  Format: Script-Literal oder Script-Variable
  
• EXTERNAL
  Ersetzt eine externe Abhängigkeit
• Workflow name
  Name des Workflows, auf den sich die externe Abhängigkeit bezieht
  Format: Script-Literal oder Script-Variable

Beispiel

Das folgende Beispiel verwendet MODIFY_TASK mit REPLACE_TASK, um eine externe Abhängigkeit (MM.GET.FILES) durch eine andere externe Abhängigkeit (MM.FILE.INPUT) zu ersetzen.

:SET &RUNID# = GET_UC_OBJECT_NR("MM.DAY")
:SET &RETSTOP# = MODIFY_TASK(&RUNID#, STOP_MODIFY)
:SET &RET# = MODIFY_TASK(&RUNID#, "MM.GET.FILES",, REPLACE_TASK, "MM.FILE.INPUT", EXTERNAL)
:SET &RETCOMMIT# = MODIFY_TASK(&RUNID#, COMMIT)
:SET &RETGO# = MODIFY_TASK(&RUNID#, GO)

Aufgabe in einen Workflow verschieben

Wenn Sie MODIFY_TASK zum Hinzufügen einer Aufgabe verwenden, wird die hinzugefügte Aufgabe an einer freien Stelle im Workflow platziert. Verwenden Sie MODIFY_TASK mit MOVE_TASK, um die Aufgabe an die gewünschte Stelle im Workflow zu verschieben. Geben Sie die Spalte und Zeile der gewünschten leeren Stelle an.

Syntax

MODIFY_TASK (RunID, [task name], [sequence number], MOVE_TASK , Column, Line)

Parameter

• MOVE_TASK
  Verschiebt die Aufgabe
• Column
  Nummer der Spalte, in die die Aufgabe verschoben werden soll
  Format: Script-Literal, Zahl oder Script-Variable
• Line
  Nummer der Zeile, in die die Aufgabe verschoben werden soll
  Format: Script-Literal, Zahl oder Script-Variable
  

Beispiel

Das folgende Script verschiebt die Aufgabe FILE.INPUT in die vierte Zeile der ersten Spalte.

:SET &RUNID# = GET_UC_OBJECT_NR("MM.DAY")
:SET &RETSTOP# = MODIFY_TASK(&RUNID#, STOP_MODIFY)
:SET &RET# = MODIFY_TASK(&RUNID#, "FILE.INPUT",, MOVE_TASK, 1, 4)
:SET &RETCOMMIT# = MODIFY_TASK(&RUNID#, COMMIT)
:SET &RETGO# = MODIFY_TASK(&RUNID#, GO)

Aktivieren oder Deaktivieren einer Workflow-Aufgabe

Verwenden Sie MODIFY_TASK mit ACTIVE, um eine Aufgabe zu aktivieren oder zu deaktivieren.

Syntax

MODIFY_TASK (RunID, [Task name], [sequence number], ACTIVE , YES|NO)

Parameter

• ACTIVE
  Setzt den Status der Aufgabe auf aktiv oder inaktiv
  
• YES oder NO
  Ermittelt den Status der Aufgabe:
  
  • YES
    Setzt die Workflow-Aufgabe auf aktiv
    Die Verarbeitung beginnt zur angegebenen Startzeit.
  • NO
    Setzt die Workflow-Aufgabe auf inaktiv
    Die Verarbeitung beginnt nicht zum Startzeitpunkt.

Beispiel

Das folgende Beispiel setzt den Status der Aufgabe FILE.INPUT im MM.DAY Workflow auf inaktiv.

:SET &RUNID# = GET_UC_OBJECT_NR("MM.DAY")
:SET &RETSTOP# = MODIFY_TASK(&RUNID#, STOP_MODIFY)
:SET &RET# = MODIFY_TASK(&RUNID#, "FILE.INPUT",, ACTIVE, "NO")
:SET &RETCOMMIT# = MODIFY_TASK(&RUNID#, COMMIT)
:SET &RETGO# = MODIFY_TASK(&RUNID#, GO)

Tab „Allgemein“

Mit den folgenden Schlüsselwörtern können Sie Eigenschaften ändern, die auf der Registerkarte Allgemein einer Workflow-Aufgabe festgelegt sind:

• ALIAS
  Ändert den Alias einer Aufgabe oder einer externen Abhängigkeit in einem aktiven Workflow
• ALIAS_PARENT
  Ändert den Alias des Workflows einer externen Abhängigkeit
• BREAKPOINT
  Setzen eines Haltepunktes in einer Workflow-Aufgabe

Weitere Informationen zu allgemeinen Eigenschaften von Aufgaben in Workflows finden Sie unter Tab „Allgemein“.

Ändern eines Task-Alias

Verwenden Sie MODIFY_TASK mit ALIAS, um den Alias einer Aufgabe oder einer externen Abhängigkeit in einem aktiven Workflow zu ändern.

Hinweis: Sie können den Alias von Workflow-Aufgaben und externen Abhängigkeiten, die Sie hinzugefügt haben, nur mit einerMODIFY_TASK, ADD_TASK-Anweisung im Script ändern.

Syntax

MODIFY_TASK (RunID,[Task name], [sequence number],ALIAS|ALIAS_PARENT, New Alias|New Parent Alias)

Parameter

Diese Funktion hat die folgenden Parameter:

• ALIAS oder ALIAS_PARENT
  Ändert den Aliasnamen einer Aufgabe oder einer externen Abhängigkeit im Workflow
  Verwenden Sie ALIAS_PARENT, um den Alias des Workflows einer externen Abhängigkeit zu ändern (nur für externe Aufgaben, die aus einem anderen Workflow stammen).
• New Alias oder Parent Alias Name
  Neuer Aliasname
  Format: AE-Name, Script-Literal, Zahl oder Script-Variable
  Weitere Informationen zu Aliasnamen finden Sie unter Tab „Allgemein“.

Beispiel

Das folgende Beispiel fügt dem Workflow einen File Transfer hinzu und ändert den Alias der Aufgabe. Der Rückgabewert vonMODIFY_TASK, ADD_TASK ist die Sequenznummer der hinzugefügten Aufgabe und wird in einer Script-Variablen (&NR#) gespeichert. Die Script-Variable wird verwendet, um anzugeben, welcher Alias geändert werden soll.

:SET &RUNID# = GET_UC_OBJECT_NR("MM.DAY")
:SET &RETSTOP# = MODIFY_TASK(&RUNID#, STOP_MODIFY)
:SET &NR# = MODIFY_TASK(&RUNID#, "FILE.INPUT",, ADD_TASK)
:SET &RET# = MODIFY_TASK(&RUNID#, "FILE.INPUT",&NR#,ALIAS,ALIAS.FT)
:SET &RETCOMMIT# = MODIFY_TASK(&RUNID#, COMMIT)
:SET &RETGO# = MODIFY_TASK(&RUNID#, GO) 

Setzen oder Entfernen eines Haltepunktes

Verwenden Sie MODIFY_TASK mit BREAKPOINT, um einen Haltepunkt in einer Workflow-Aufgabe zu setzen oder zu entfernen.

Syntax

MODIFY_TASK (RunID, [Task name], [sequence number], BREAKPOINT, YES|NO)

Parameter

• BREAKPOINT
  Setzt oder entfernt den Haltepunkt für die Workflow-Aufgabe
• YES oder NO
  Legt fest, ob das Schlüsselwort einen Haltepunkt hinzufügt oder entfernt:
  • YES
    Setzt einen Haltepunkt
  • NO
    Entfernt den Haltepunkt
    

Beispiel

Das folgende Beispiel verwendet MODIFY_TASK mit dem Schlüsselwort BREAKPOINT, um einen Haltepunkt für die Aufgabe FILE.INPUT zu setzen.

:SET &RUNID# = GET_UC_OBJECT_NR("MM.DAY")
:SET &RETSTOP# = MODIFY_TASK(&RUNID#, STOP_MODIFY)
:SET &RET# = MODIFY_TASK(&RUNID#, "FILE.INPUT",, BREAKPOINT, "YES")
:SET &RETCOMMIT# = MODIFY_TASK(&RUNID#, COMMIT)
:SET &RETGO# = MODIFY_TASK(&RUNID#, GO)

Registerkarte „Zeit & Abhängigkeiten“

Mit den folgenden Schlüsselwörtern können Sie Eigenschaften ändern, die auf der Registerkarte Zeit & Abhängigkeiten einer Workflow-Aufgabe festgelegt sind:

• EARLIEST_START
  Setzt eine früheste Startzeit für eine Workflow-Aufgabe
• LATEST_START
  Fügt eine späteste Startzeit für eine Workflow-Aufgabe hinzu oder entfernt sie
• CHECKPOINT
  Fügt einen Kontrollpunkt in einer Workflow-Aufgabe hinzu oder entfernt ihn
• DEPENDENCY_STATE_MATCH
  Anzahl der Zustände der Vorgängeraufgabe, die zutreffen müssen

Weitere Informationen zu Eigenschaften, die das Timing und die Abhängigkeiten bestimmen, finden Sie unter Zeit & Abhängigkeiten.

Hinzufügen oder Entfernen einer Start- oder Endzeit

Verwenden Sie MODIFY_TASK mit einem Start- oder Endschlüsselwort, um die Start- oder Endzeit einer Aufgabe in einem aktiven Workflow festzulegen oder zu entfernen.

Syntax

MODIFY_TASK (RunID, [Task name], [sequence number], KEYWORD, Timestamp [, Time zone])

Parameter

• KEYWORD
  Setzt oder entfernt die Start- oder Endzeit der Aufgabe:
  • EARLIEST_START
    Setzt oder entfernt die früheste Startzeit der Aufgabe
  • LATEST_START
    Setzt oder entfernt die letzte Startzeit der Aufgabe
  • LATEST_END
    Setzt oder entfernt die letzte Endzeit der Aufgabe
• Timestamp
  Definiert die Zeit
  Format: Script-Literal oder Script-Variable
  Erlaubte Werte: TT/HH:MM [, Time zone]
  Ist die
  Wobei:
  • TT
    Anzahl der Tage, die zum aktuellen Datum hinzugefügt werden sollen
  • HH:MM
    Zeit
  • Time zone
    (Optional) Name eines Zeitzonenobjekts, um die Zeit in eine bestimmte Zeitzone zu konvertieren
    Format: Script-Literal oder Script-Variable
    Weitere Informationen finden Sie unter Zeitzone (TZ).

Hinweis: Der Vergleichswert für die früheste Startzeit ist das reale Datum (der Zeitpunkt, zu dem der oberste Workflow erzeugt wird). Weitere Informationen finden Sie unter Logisches Datum und reales Datum

Beispiele

Das folgende Beispiel setzt die früheste Startzeit für die Aufgabe FILE.INPUT.

:SET &RUNID# = GET_UC_OBJECT_NR("MM.DAY")
:SET &RETSTOP# = MODIFY_TASK(&RUNID#, STOP_MODIFY)
:SET &RET# = MODIFY_TASK(&RUNID#, "FILE.INPUT",, EARLIEST_START, "00/18:00")
:SET &RETCOMMIT# = MODIFY_TASK(&RUNID#, COMMIT)
:SET &RETGO# = MODIFY_TASK(&RUNID#, GO)

Das folgende Beispiel setzt die späteste Startzeit für die Aufgabe.

:SET &RUNID# = GET_UC_OBJECT_NR("MM.DAY")
:SET &RETSTOP# = MODIFY_TASK(&RUNID#, STOP_MODIFY)
:SET &RET# = MODIFY_TASK(&RUNID#, "FILE.INPUT",, LATEST_START, "00/10:00")
:SET &RETCOMMIT# = MODIFY_TASK(&RUNID#, COMMIT)
:SET &RETGO# = MODIFY_TASK(&RUNID#, GO)

Das folgende Beispiel setzt die späteste Endzeit für die Aufgabe.

:SET &RUNID# = GET_UC_OBJECT_NR("MM.DAY")
:SET &RETSTOP# = MODIFY_TASK(&RUNID#, STOP_MODIFY)
:SET &RET# = MODIFY_TASK(&RUNID#, "FILE.INPUT",, LATEST_END, "00/18:00")
:SET &RETCOMMIT# = MODIFY_TASK(&RUNID#, COMMIT)
:SET &RETGO# = MODIFY_TASK(&RUNID#, GO)

Hinzufügen oder Entfernen eines Kontrollpunkts

Verwenden Sie MODIFY_TASK mit CHECKPOINT, um einen Kontrollpunkt in einer Aufgabe eines aktiven Workflows hinzuzufügen oder zu entfernen.

Syntax

MODIFY_TASK (RunID, [task name], [sequence number], CHECKPOINT, timestamp [, Time Zone] [, Alarm object])

Parameter

• CHECKPOINT
  Setzt oder entfernt einen Kontrollpunkt
  
• Alarm object
  (Optional) Objekt, das gestartet werden soll, wenn der Kontrollpunkt passiert wird
  Format: Script-Literal oder Script-Variable
  

Beispiel

Das folgende Beispiel setzt einen Kontrollpunkt in einer Aufgabe namens FILE.INPUT, die Teil des MM.DAY-Workflows ist. Nach Ablauf des Kontrollpunkts startet ein Benachrichtigungsobjekt mit dem Namen DAYSHIFT.

:SET &RUNID# = GET_UC_OBJECT_NR("MM.DAY")
:SET &RETSTOP# = MODIFY_TASK(&RUNID#, STOP_MODIFY)
:SET &RET# = MODIFY_TASK(&RUNID#, "FILE.INPUT",, CHECKPOINT, "00/15:00",,"DAYSHIFT")
:SET &RETCOMMIT# = MODIFY_TASK(&RUNID#, COMMIT)
:SET &RETGO# = MODIFY_TASK(&RUNID#, GO)

Ermitteln der Anzahl der erforderlichen Status der Vorgänger

Verwenden Sie MODIFY_TASK mit DEPENDENCY_STATE_MATCH, um festzulegen, ob ein oder alle Status der Vorgänger gelten müssen, bevor die Workflow-Aufgabe bearbeitet wird. Auf der Registerkarte Zeit & Abhängigkeiten in den Aufgabeneigenschaften trägt diese Einstellung die Bezeichnung Diese Aufgabe ausführen, wenn alle Status übereinstimmen/ mindestens eine Bedingung erfüllt ist.

Syntax

MODIFY_TASK (RunID, [Task name], [sequence number], DEPENDENCY_STATE_MATCH , ALL|ONE)

Parameter

• DEPENDENCY_STATE_MATCH
  Gibt die Anzahl der Vorgängerstatus an, die zutreffen müssen
• ALL oder ONE
  Wie viele Vorgängerstatus müssen zutreffen:
  • ALL
    Alle Status müssen zutreffen
  • ONE
    Mindestens ein Status muss zutreffen
    

Beispiel

Das folgende Beispiel verwendet MODIFY_TASK mit dem DEPENDENCY_STATE_MATCH-Schlüsselwort, um sicherzustellen, dass alle Vorgänger der Aufgabe FILE.INPUT den erwarteten Status haben müssen, bevor die Aufgabe bearbeitet wird.

:SET &RUNID# = GET_UC_OBJECT_NR("MM.DAY")
:SET &RETSTOP# = MODIFY_TASK(&RUNID#, STOP_MODIFY)
:SET &RET# = MODIFY_TASK(&RUNID#, "FILE.INPUT",, DEPENDENCY_STATE_MATCH, "ALL")
:SET &RETCOMMIT# = MODIFY_TASK(&RUNID#, COMMIT)
:SET &RETGO# = MODIFY_TASK(&RUNID#, GO)

Hinzufügen, Ändern oder Entfernen einer Abhängigkeit zu einer Workflow-Aufgabe

Verwenden Sie MODIFY_TASK mit einem Schlüsselwort DEPENDENCY, um eine Abhängigkeit zu einer Aufgabe in einem Workflow hinzuzufügen, zu entfernen oder zu ändern. Die Funktion fügt Zeilen hinzu, entfernt oder ändert sie, die Aufgaben im Workflow-Editor verbinden.

Syntax

MODIFY_TASK (RunID, [successor task name], [sequence number], ADD_DEPENDENCY|MODIFY_DEPENDENCY|REMOVE_DEPENDENCY, [source task name] , [sequence number], status)

Parameter

• successor task name oder sequence number
  Name oder Sequenznummer der Nachfolgeaufgabe der Abhängigkeit
  Format: Script-Literal, Zahl oder Script-Variable
  
• ADD_DEPENDENCYoder MODIFY_DEPENDENCYoder REMOVE_DEPENDENCY
  Fügt die Abhängigkeit hinzu, ändert oder entfernt sie
• source task name oder sequence number
  Name oder Sequenznummer der Aufgabe, deren Abhängigkeit Sie bearbeiten möchten
  Format: Script-Literal, Zahl oder Script-Variable
• status
  Erwarteter Status der vorhergehenden Aufgabe am Ende der Ausführung der Aufgabe
  Format: Script-Literal oder Script-Variable
  Hinweis: Sie müssen beim Entfernen einer Abhängigkeit keinen Status angeben.
  Erlaubte Werte:
  • Endstatus
    Erwarteter Status der Vorgängeraufgabe
    Beispiel: ENDED_OK
  • NONE
    Der Endstatus der Vorgängeraufgabe wird nicht überwacht

Weitere Informationen zur Angabe von Aufgabennamen und laufenden Nummern finden Sie unter Syntax und Parameter .

Beispiel

Das folgende Beispiel bearbeitet Abhängigkeiten im Workflow:

• Die vierte Aufgabe erfordert, dass das Startfeld den Status ENDED_OK erhält.
• Die 9. Aufgabe erfordert die 8. Aufgabe, um den ANY_OK-Status zu erhalten.
• Die Abhängigkeit der 11. Aufgabe von der 10. Aufgabe wird aufgehoben.

:SET &RUNID# = GET_UC_OBJECT_NR("MM.DAY")
:SET &RETSTOP# = MODIFY_TASK(&RUNID#, STOP_MODIFY)
:SET &RET# = MODIFY_TASK(&RUNID#,, 4, ADD_DEPENDENCY, "START",, "ENDED_OK")
:SET &RET# = MODIFY_TASK(&RUNID#,, 9, MODIFY_DEPENDENCY,, 8,"ANY_OK")
:SET &RET# = MODIFY_TASK(&RUNID#,, 11, REMOVE_DEPENDENCY,, 10, "ENDED_OK")
:SET &RETCOMMIT# = MODIFY_TASK(&RUNID#, COMMIT)
:SET &RETGO# = MODIFY_TASK(&RUNID#, GO)

Definition einer Aktion, die ergriffen werden soll, wenn Abhängigkeiten nicht erfüllt werden

Verwenden Sie MODIFY_TASK mit DEPENDENCY_ELSE_ACTION, um die Aktion zu definieren, die durchgeführt werden soll, wenn eine Abhängigkeit nicht erfüllt ist.

Syntax

MODIFY_TASK (RunID, [Task name], [sequence number], DEPENDENCY_ELSE_ACTION , ABORT|BLOCK|BLOCK_ABORT|SKIP [ , Alarm object] )

Parameter

• DEPENDENCY_ELSE_ACTION
  Legt fest, dass Maßnahmen ergriffen werden sollen, wenn Abhängigkeiten nicht wie erwartet erfüllt werden
• ABORT, BLOCK, BLOCK_ABORT oder SKIP
  Definiert die zu ergreifenden Maßnahmen:
  • ABBRECHEN
    Die Aufgabe und der Workflow werden abgebrochen
  • BLOCK
    Der Workflow blockiert bei der Vorgängeraufgabe
  • BLOCK_ABORT
    Blockiert den Workflow bei der vorhergehenden Aufgabe und sendet und bricht die Meldung gegebenenfalls an den übergeordneten Workflow ab
  • SKIP
    Überspringt die Workflow-Aufgabe
• Alarm object
  Name eines Benachrichtigungsobjekts des Alarmtyps, das gestartet werden soll, wenn der Kontrollpunkt überschritten wird
  Format: Script-Literal oder Script-Variable
  

Beispiel

Das folgende Beispiel überspringt die Aufgabe FILE.INPUT, wenn die Bedingungen für die Abhängigkeit nicht erfüllt sind.

:SET &RUNID# = GET_UC_OBJECT_NR("MM.DAY")
:SET &RETSTOP# = MODIFY_TASK(&RUNID#, STOP_MODIFY)
:SET &RET# = MODIFY_TASK(&RUNID#, "FILE.INPUT",, DEPENDENCY_ELSE_ACTION, "SKIP")
:SET &RETCOMMIT# = MODIFY_TASK(&RUNID#, COMMIT)
:SET &RETGO# = MODIFY_TASK(&RUNID#, GO)

Registerkarte „Laufzeit“

Mit den folgenden Parametern können Sie die Einstellungen auf der Registerkarte Runtime einer Workflow-Aufgabe ändern. Weitere Informationen finden Sie unter Laufzeit-Eigenschaften.

Syntax

MODIFY_TASK (RunID, [task name], [sequence number], runtime option, value )

Parameter

• runtime option
  Laufzeiteinstellung, die Sie bearbeiten möchten
• value
  Definiert den Wert für die Einstellung, abhängig von der Laufzeiteinstellung, die Sie bearbeiten möchten
  

Laufzeit-Optionen:

• RUNTIME_USE_TASK_SETTINGS
  Verwendet die MRT- und SRT-Einstellungen der Aufgabe
  Erlaubte Werte:
  

  • YES
    Verwendet die für die Aufgabe auf der Registerkarte Laufzeit definierten Laufzeiteinstellungen (Aufgabeneigenschaften im Workflow)
  • NO
    Verwendet die Laufzeiteinstellungen, die in den Eigenschaften auf der Seite Laufzeit in der Objektdefinition definiert sind

• RUNTIME_MRT_NONE
  Keine angegebene maximale Laufzeit
  Geben Sie keinen Wert ein.

• RUNTIME_MRT_FIXED
  Verwendung eines Festwertes für die maximale Laufzeit
  Erlaubte Werte: Festwert im Format HHHHH:MM:SS

• RUNTIME_MRT_ERT
  Verwendet ERT plus einen Prozentsatz für die maximale Laufzeit
  Erlaubte Werte: Prozentsatz
  Beispiel: Schreiben Sie 50, um 50% zur maximalen Laufzeit hinzuzufügen.

• RUNTIME_MRT_TIME
  Verwendet das aktuelle Datum plus einen Zeitraum für die maximale Laufzeit
  Erlaubte Werte: TT/HH:MM [, Time zone]
  Wobei:

  • TT
    Anzahl der Tage, die zum aktuellen Datum hinzugefügt werden sollen
  • HH:MM
    Zeit
  • Time zone
    (Optional) Name eines Zeitzonenobjekts, um den Zeitstempel zu konvertieren

• RUNTIME_SRT_NONE
  Keine minimale Laufzeit
  Geben Sie keinen Wert ein.

• RUNTIME_SRT_FIXED
  Festwert für die minimale Laufzeit
  Erlaubte Werte: Festwert im Format HHHHH:MM:SS

• RUNTIME_SRT_ERT
  Verwendet ERT minus einen Prozentsatz für die minimale Laufzeit
  Erlaubte Werte: Prozentsatz

• RUNTIME_ELSE_ACTION
  Definiert eine Aktion, die ausgeführt werden soll, wenn die tatsächliche Laufzeit von der erwarteten Laufzeit abweicht
  Erlaubte Werte: CANCEL|NONE [, Alarm object]
  Wobei:
  

  • CANCEL
    Bricht die Aufgabe ab oder beendet sie
  • NONE
    Es werden keine Maßnahmen ergriffen
  • Alarm object
    (Optional) Name eines Benachrichtigungsobjekts eines Alarmtyps, das gestartet werden soll, wenn die erwartete Laufzeit überschritten wird

Beispiel

Das Benachrichtigungsobjekt DAYSHIFT startet, wenn die Ausführung der Aufgabe FILE.INPUT länger als zwei Stunden dauert. Das Script entfernt auch alle minimalen Laufzeiteinstellungen.

:SET &RUNID# = GET_UC_OBJECT_NR("MM.DAY")
:SET &RETSTOP# = MODIFY_TASK(&RUNID#, STOP_MODIFY)
:SET &RETMRT# = MODIFY_TASK(&RUNID#, "FILE.INPUT",, RUNTIME_MRT_FIXED, "2:00:00")
:SET  &RETSRT# = MODIFY_TASK(&RUNID#, "FILE.INPUT",, RUNTIME_SRT_NONE)
:SET  &RETACT# = MODIFY_TASK(&RUNID#, "FILE.INPUT",, RUNTIME_ELSE_ACTION,"CANCEL", "DAYSHIFT")
:SET &RETCOMMIT# = MODIFY_TASK(&RUNID#, COMMIT)
:SET &RETGO# = MODIFY_TASK(&RUNID#, GO)

Tab „Externe Abhängigkeit“

Mit den folgenden Schlüsselwörtern können Sie die Einstellungen auf der Registerkarte Externe Abhängigkeiten einer externen Aufgabe in einem Workflow ändern.

• EXTERNAL_SATISFACTION
  Definiert, wann das Ende einer externen Aufgabe erwartet wird
• EXTERNAL_STATUS
  Setzt den erwarteten Status einer externen Aufgabe
• EXTERNAL_ELSE_ACTION
  Definiert die Maßnahmen, die ergriffen werden müssen, wenn eine externe Aufgabe die Erwartungen nicht erfüllt
• EXTERNAL_TIMEOUT_ACTION
  Definiert die Maßnahmen, die ergriffen werden müssen, wenn eine externe Aufgabe ausfällt

Mehr Informationen:

• Externe Abhängigkeiten in Workflows
• Tab „Externe Abhängigkeit“

Ausführungseinstellungen einer externen Abhängigkeit definieren

Verwenden Sie MODIFY_TASK mit EXTERNAL_SATISFACTION, um zu definieren, wie der Workflow mit einer externen Abhängigkeit umgeht. Der Workflow ist so konfiguriert, dass erwartet wird, dass die externe Aufgabe zu einem bestimmten Zeitpunkt beginnt oder endet, z.B. vor oder nach dem Start des aktuellen Workflows. MitEXTERNAL_SATISFACTION können Sie die Einstellungen ändern, die die erwartete Durchlaufzeit bestimmen.

Syntax

MODIFY_TASK (RunID, [task name], [sequence number],EXTERNAL_SATISFACTION , lead time satisfaction [, duration])

Parameter

• EXTERNAL_SATISFACTION
  Definiert den Erfüllungszeitraum
• lead time satisfaction
  Legt fest, wann die externe Abhängigkeit als Erfüllung der Erwartungen angesehen wird:
  • LOGICAL_DATE
    Überprüfen Sie, ob die externe Aufgabe mit demselben logischen Datum aktiviert wurde wie der Workflow
  • LAST_EXECUTION
    Überprüft, ob das Ende der externen Aufgabe nach dem Ende der letzten Workflow-Durchführung liegt
  • BEFORE_START
    Überprüft, ob das Ende der externen Aufgabe innerhalb eines Zeitraumes vor dem Workflow-Start liegt
  • AFTER_START
    Überprüft, ob das Ende der externen Aufgabe nach dem aktuellen Workflow-Start liegt
• duration
  (nur BEFORE_START) Zeitraum im Format HH:MM:SS
  Format: Script-Literal oder Script-Variable
  

Beispiel

Im folgenden Beispiel beginnt der Erfüllungszeitraum für die externe Abhängigkeit MM.GET.FILES mit dem Start des Workflows.

:SET &RUNID# = GET_UC_OBJECT_NR("MM.DAY")
:SET &RETSTOP# = MODIFY_TASK(&RUNID#, STOP_MODIFY)
:SET &RET# = MODIFY_TASK(&RUNID#, "MM.GET.FILES",, EXTERNAL_SATISFACTION, "AFTER_START")
:SET &RETCOMMIT# = MODIFY_TASK(&RUNID#, COMMIT)
:SET &RETGO# = MODIFY_TASK(&RUNID#, GO)

Setzen des erwarteten Status einer externen Abhängigkeit

Verwenden Sie MODIFY_TASK mit EXTERNAL_STATUS, um den Status zu setzen, der für eine externe Aufgabe erwartet wird.

Syntax

MODIFY_TASK (RunID, [task name], [sequence number], EXTERNAL_STATUS , status)

Parameter

• EXTERNAL_STATUS
  Setzt oder entfernt den erwarteten Status einer externen Aufgabe
• status
  Erwarteter Status für die externe Aufgabe:
  • Endstatus
    Status wie z.B. ENDED_OK
  • NONE
    Das System prüft nur, ob die Aufgabe innerhalb des Erfüllungszeitraums beendet wurde, unabhängig vom Status

Beispiel

Im folgenden Beispiel erwartet der MM.DAY Workflow einen ENDED_OK-Status von der externen Aufgabe MM.GET.FILES.

:SET &RUNID# = GET_UC_OBJECT_NR("MM.DAY")
:SET &RETSTOP# = MODIFY_TASK(&RUNID#, STOP_MODIFY)
:SET &RET# = MODIFY_TASK(&RUNID#, "MM.GET.FILES",, EXTERNAL_STATUS, "ENDED_OK")
:SET &RETCOMMIT# = MODIFY_TASK(&RUNID#, COMMIT)
:SET &RETGO# = MODIFY_TASK(&RUNID#, GO)

Definition der Sonst-Aktion einer externen Abhängigkeit

Verwenden Sie MODIFY_TASK mit EXTERNAL_ELSE_ACTION, um die zu ergreifende Maßnahme zu definieren, wenn eine externe Aufgabe nicht den erwarteten Status erhält oder nicht innerhalb der erwarteten Zeit endet.

Syntax

MODIFY_TASK (RunID, [task name], [sequence number], EXTERNAL_ELSE_ACTION , WAIT|SKIP|CANCEL [, Alarm object] )

Parameter

• EXTERNAL_ELSE_ACTION
  Legt fest, dass Maßnahmen ergriffen werden sollen, wenn eine externe Aufgabe mindestens einmal den erwarteten Status nicht erhält oder nicht innerhalb der erwarteten Zeit endet
• WAIT, SKIP, oder CANCEL
  Definiert die zu ergreifenden Maßnahmen:
  • WAIT
    Wartet darauf, dass die externe Aufgabe abgeschlossen ist
    Hinweis: Verwenden Sie MODIFY_TASK mit EXTERNAL_TIMEOUT_ACTION, um den Timeout für diese Aktion zu definieren.
  • SKIP
    Überspringt die externe Aufgabe
  • CANCEL
    Bricht den Workflow ab
• Alarm object
  (Optionall) Name eines Benachrichtigungsobjekts eines Alarmtyps, das bei Auftreten eines Timeout gestartet werden soll
  Format: Script-Literal oder Script-Variable
  

Beispiel

Im folgenden Beispiel wird der MM.DAY-Workflow abgebrochen, wenn die externe Aufgabe MM.GET.FILES nicht wie erwartet endet. Wenn das Script den Workflow abbricht, startet es ein Benachrichtigungsobjekt namens DAYSHIFT.

:SET &RUNID# = GET_UC_OBJECT_NR("MM.DAY")
:SET &RETSTOP# = MODIFY_TASK(&RUNID#, STOP_MODIFY)
:SET &RET# = MODIFY_TASK(&RUNID#, "MM.GET.FILES",, EXTERNAL_ELSE_ACTION, "CANCEL", "DAYSHIFT")
:SET &RETCOMMIT# = MODIFY_TASK(&RUNID#, COMMIT)
:SET &RETGO# = MODIFY_TASK(&RUNID#, GO)

Definition der Timeout-Einstellung einer externen Abhängigkeit

Verwenden Sie MODIFY_TASK mit EXTERNAL_TIMEOUT_ACTION, um die Timeout-Einstellung einer externen Aufgabe zu definieren, wenn Sie WAIT verwenden, und definieren Sie eine Sonst-Aktion.

Syntax

MODIFY_TASK (RunID, [task name], [sequence number], EXTERNAL_TIMEOUT_ACTION , timeout length, WAIT|SKIP|CANCEL[, Alarm object])

Parameter

• EXTERNAL_TIMEOUT_ACTION
  Legt die Wartezeit fest, wenn Sie eine Sonst-Aktion mit WAIT definieren
• timeout length
  Timeout-Dauer im Format HH:MM:SS
  Format: Script-Literal oder Script-Variable
• WAIT, SKIP oder CANCEL
  Definiert die zu ergreifenden Maßnahmen:
  • WAIT
    Wartet darauf, dass die externe Aufgabe abgeschlossen ist
  • SKIP
    Überspringt die externe Aufgabe
  • CANCEL
    Bricht den Workflow ab
• Alarm object
  (Optional) Name eines Benachrichtigungsobjekts eines Alarmtyps, das bei Auftreten eines Timeout gestartet werden soll
  Format: Script-Literal oder Script-Variable
  

Beispiel

Im folgenden Workflow besteht eine externe Abhängigkeit von einer Aufgabe mit dem Namen MM.GET.FILES. Der Workflow überspringt die externe Aufgabe, wenn die Aufgabe nicht wie erwartet innerhalb einer Stunde endet.

:SET &RUNID# = GET_UC_OBJECT_NR("MM.DAY")
:SET &RETSTOP# = MODIFY_TASK(&RUNID#, STOP_MODIFY)
:SET &RET# = MODIFY_TASK(&RUNID#, "MM.GET.FILES",, EXTERNAL_TIMEOUT_ACTION, "01:00:00", "SKIP")
:SET &RETCOMMIT# = MODIFY_TASK(&RUNID#, COMMIT)
:SET &RETGO# = MODIFY_TASK(&RUNID#, GO)

Ändert den Wert einer Variablen

Verwenden Sie MODIFY_TASK mit VALUE, um den Wert einer Variablen zu ändern, die auf der Registerkarte Variablen & Prompts gespeichert ist:

• Objektvariable
  Ändern Sie einen vorhandenen Variablenwert oder erstellen Sie eine neue Variable mit einem bestimmten Wert.
• PromptSet-Variable
  Ändern eines vorhandenen Variablenwerts eines PromptSet-Controls.

• Seite „Variablen“
• Seite „PromptSets“

Syntax

MODIFY_TASK (RunID, task name, sequence number, VALUE,PROMPTSET NAME|<VALUE>, VARIABLE|NEW VARIABLE, "VALUE", [SELECT|DESELECT|CLEAR|SPACE])

Parameter

• VALUE
  Ändert den Wert einer Variablen:
  • Ändert den Wert einer vorhandenen Objektvariablen oder erstellt eine neue Objektvariable
  • Ändert den Wert einer vorhandenen PromptSet-Variablen
• PromptSet Name oder <VALUE>
  Bestimmt die Variable:
  • PromptSet-Name
    Name des PromptSet-Objekts
  • <VALUE>
    Name der Objektvariablen
• Variable
  (nur Objektvariablen) Name der neuen Variable, wenn die Objektvariable noch nicht vorhanden ist
  Hinweis: Schreiben Sie den Variablennamen ohne das führende kaufmännischen Und-Zeichen
• Value
  (Optional) Zu setzender Wert für die Variable
  Hinweis: Sie müssen einen Wert setzen, wenn Sie eine PromptSet-Variable ändern, die ein Array ist.
  Format: Script-Literal oder Script-Variable
• SELECT, DESELECT, CLEAR oder SPACE
  (Optional) Ändert die in der Variablen ausgewählten Werte:
  • SELECT
    (Nur PromptSet-Variablen-Arrays) Wählt Zeilen eines Arrays aus
  • DESELECT
    (Nur PromptSet-Variablen-Arrays) Deselektiert die Zeilen eines Arrays
  • CLEAR
    (Nur PromptSet-Variablen-Arrays) Deselektiert alle Zeilen eines Arrays
  • SPACE (Standard)
    Ändert den Wert der PromptSet-Variablen oder Objektvariablen in leeren Text
  Hinweis: Mit diesen Schlüsselwörtern können Sie Werte auswählen oder deselektieren, wenn die Variable mehrere Werte zulässt. Verwenden Sie diese Parameter, um Werte aus PromptSet-Controls, wie Kontrollkästchen, zu verwalten. Bei den ausgewählten Werten kann es sich um benutzerselektierte Werte, Standardwerte oder Werte handeln, die für den Workflow definiert wurden.

Beispiele

Im folgenden Beispiel aktiviert das Script einen Workflow und stoppt den Workflow bei Änderungen. Das Script erstellt eine Variable und weist der Variablen einen Wert zu.

:SET &RUNID# = ACTIVATE_UC_OBJECT("JOBP.NEW.01")
:SET &RETSTOP# = MODIFY_TASK(&RUNID#, STOP_MODIFY)
:SET &MODIFY# = MODIFY_TASK(&RUNID#, "SCRI.NEW.01", 4, VALUE, "<VALUE>", "&&VARIABLE#", "Vienna")
:SET &RETCOMMIT# = MODIFY_TASK(&RUNID#, COMMIT)
:SET &RETGO# = MODIFY_TASK(&RUNID#, GO)

Im folgenden Beispiel hat ein Script-Objekt ein zugewiesenes PromptSet. Das Script ändert die Werte der PromptSet-Variablen CKG#, d.h. ein Array von Werten aus einem Checklisten-Control. Die Parameter in MODIFY_TASK, VALUE wählen den Wert „Test01“ aus der Variable PromptSet aus.

:SET &RUNID# = ACTIVATE_UC_OBJECT("JOBP.NEW.01")
:SET &RETSTOP# = MODIFY_TASK(&RUNID#, STOP_MODIFY)
:SET &MODIFY#= MODIFY_TASK(&RUNID#, "SCRI.NEW.01", 4, VALUE, "PRPT.NEW.01", "CKG#", "Test01", SELECT)
:SET &RETCOMMIT# = MODIFY_TASK(&RUNID#, COMMIT)
:SET &RETGO# = MODIFY_TASK(&RUNID#, GO)

Im folgenden Beispiel wird der Wert der PromptSet-Variablen Textfield01# auf mytextfieldvalue gesetzt.

:SET &RUNID# = ACTIVATE_UC_OBJECT("JOBP.NEW.01")
:SET &RETSTOP# = MODIFY_TASK(&RUNID#, STOP_MODIFY)
:SET &MODIFY# = MODIFY_TASK(&RUNID#, "SCRI.NEW.01", 4, VALUE, "PRPT.NEW.01", "Textfield01#", "mytexfieldvalue")
:SET &RETCOMMIT# = MODIFY_TASK(&RUNID#, COMMIT)
:SET &RETGO# = MODIFY_TASK(&RUNID#, GO)

Siehe auch: